PKGBUILDs/extra/x264/PKGBUILD

# $Id: PKGBUILD 149275 2012-02-06 17:33:29Z ibiru $
# Maintainer : Ionut Biru <ibiru@archlinux.org>
# Contributor: damir <damir@archlinux.org>
# Contributor: Paul Mattal <paul@archlinux.org>

# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
#  - configure needs --disable-asm to build on ARM

pkgname=x264
pkgver=20130702
pkgrel=1
pkgdesc="free library for encoding H264/AVC video streams"
arch=('i686' 'x86_64')
url="http://www.videolan.org/developers/x264.html"
license=('GPL')
depends=('glibc')
makedepends=('yasm' 'git')
source=(git://git.videolan.org/x264.git#commit=585324fee3)
md5sums=('SKIP')

[[ "$CARCH" == "i686" ]] && _asm='--disable-asm'
[[ "$CARCH" == "arm" ]] && _asm='--disable-asm'
[[ "$CARCH" == "armv6h" ]] && _asm='--disable-asm'
[[ "$CARCH" == "armv7h" ]] && _asm='--disable-asm'

pkgver() {
  cd $pkgname
  git log -1 --format="%cd" --date=short | sed 's|-||g'
}

build() {
  cd $pkgname

  ./configure --enable-shared \
    --enable-pic \
    $_asm
  make
}

package() {
  cd $pkgname

  make DESTDIR="$pkgdir" \
    bindir=/usr/bin \
    libdir=/usr/lib \
    includedir=/usr/include \
    install
}

# vim:set ts=2 sw=2 et: