PKGBUILDs/extra/avogadro/PKGBUILD

# $Id$
# Maintainer:
# Contributor: Andrea Scarpino <andrea@archlinux.org>
# Contributor: Nick B <Shirakawasuna at gmail _dot_com>

# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
#  - patch to fix FTBFS on ARM

pkgname=avogadro
pkgver=1.1.1
pkgrel=8
pkgdesc="An advanced molecular editor based on Qt"
arch=('i686' 'x86_64')
url="http://avogadro.openmolecules.net/wiki/Main_Page"
license=('GPL2')
depends=('openbabel' 'python2-pyqt4' 'boost-libs' 'glew' 'python2-numpy')
makedepends=('cmake' 'boost' 'doxygen' 'mesa-libgl' 'eigen2')
install=avogadro.install
source=("http://downloads.sourceforge.net/${pkgname}/${pkgname}-${pkgver}.tar.bz2"
        'boost153.patch'
        'https://github.com/cryos/avogadro/commit/6f1a111bab5798a4289187bdf747c3be4e176534.patch')
md5sums=('1223bb18f50dccd2c60538aa90d58c7a'
         'aa2573f78d5dbd85b3cb79e08acde8ab'
         'eac1985ccd6ea8d6549b451ee0f68c45')

prepare() {
  mkdir build

  cd ${pkgname}-${pkgver}
  patch -p1 -i "${srcdir}"/boost153.patch
  patch -p1 -i ../6f1a111bab5798a4289187bdf747c3be4e176534.patch
}

build() {
  cd build

  export CXXFLAGS="$CXXFLAGS -lX11 -lopenbabel"
  cmake ../${pkgname}-${pkgver} \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DPYTHON_EXECUTABLE=/usr/bin/python2 \
    -DQT_MKSPECS_RELATIVE=share/qt4/mkspecs
  make
}

package() {
  cd build
  make DESTDIR="${pkgdir}" install
}