PKGBUILDs/alarm/raspberrypi-firmware/PKGBUILD

buildarch=18

pkgname=raspberrypi-firmware
pkgver=20121126
pkgrel=1
pkgdesc="Firmware files for Raspberry Pi"
arch=('any')
url="https://github.com/raspberrypi/firmware"
makedepends=('git')
license=('custom')
options=(!strip)
install=${pkgname}.install
_gitroot=git://github.com/raspberrypi/firmware.git
_gitname=firmware
provides=('raspberrypi-firmware')
conflicts=('raspberrypi-firmware-next')
replaces=('raspberrypi-firmware-next')

build() {
  msg "Connecting to GIT server...."

  if [[ -d "$_gitname" ]]; then
    cd "$_gitname" && git pull origin
    msg "The local files are updated."
  else
    git clone --depth 1 "$_gitroot" "$_gitname"
  fi

  msg "GIT checkout done or server timeout"

  rm -f "${srcdir}"/firmware/boot/kernel.img
}

package() {
  cp -R "${srcdir}"/firmware/boot "${pkgdir}"/boot
  mkdir -p "${pkgdir}"/opt/vc

  if [[ $CARCH == "arm" ]]; then
    cp -R "${srcdir}"/firmware/opt/vc/{bin,include,lib,sbin,LICENCE} "${pkgdir}"/opt/vc
  elif [[ $CARCH == "armv6h" ]]; then
    cp -R "${srcdir}"/firmware/hardfp/opt/vc/{bin,include,lib,sbin,LICENCE} "${pkgdir}"/opt/vc
  fi
}