PKGBUILDs/extra/xine-lib/PKGBUILD

# $Id$
# Maintainer: Eric Bélanger <eric@archlinux.org>

# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
#  - disabled vdpau

pkgname=xine-lib
pkgver=1.2.6
pkgrel=11
pkgdesc="A multimedia playback engine"
arch=('i686' 'x86_64')
url="http://www.xine-project.org"
license=('LGPL' 'GPL')
depends=('libxvmc' 'ffmpeg' 'libxinerama')
makedepends=('wavpack' 'faad2' 'libmng' 'imagemagick' 'mesa' 'libmodplug'
             'vcdimager' 'jack' 'aalib' 'libdca' 'a52dec' 'libmad' 'libdvdnav'
             'libmpcdec' 'libcaca' 'libbluray' 'gnome-vfs' 'glu' 'gdk-pixbuf2')
optdepends=('imagemagick: for using the imagemagick plugin' \
            'jack: for using the jack plugin' \
            'vcdimager: for using the vcd plugin' \
            'glu: for using the opengl plugin' \
            'wavpack: for using the wavpack plugin' \
            'faad2: for using the faad plugin' \
            'libmng: for using the mng plugin' \
            'aalib: for using the aalib plugin' \
            'libmodplug: for using the modplug plugin' \
            'libdca: for using the dca plugin' \
            'a52dec: for using the a52 plugin' \
            'libmad: for using the mp3 plugin' \
            'libmpcdec: for using the musepack plugin' \
            'libcaca: for using the caca plugin' \
            'libbluray: for using the bluray plugin' \
            'gnome-vfs: for using the gnome-vfs plugin' \
            'smbclient: for using the samba plugin' \
            'gdk-pixbuf2: for using the gdk-pixbuf plugin')
source=(http://downloads.sourceforge.net/sourceforge/xine/${pkgname}-${pkgver}.tar.xz xine-lib-ffmpeg3.patch xine-lib-xcb-1.12.patch)
sha1sums=('ac929eef2b7bf5c27699bbed612b953a01fccba5'
          'b4466616bb17142aef8aa1bb80fff67cd2d0d15d'
          '890c8f044c0080bfb7d4b163061dd42621fc4df1')

prepare() {
  cd $pkgname-$pkgver
# Fix build with ffmpeg 3.0 (Gentoo)
  patch -p1 -i ../xine-lib-ffmpeg3.patch
# Fix build with xcb 1.12 (Gentoo)
  patch -p1 -i ../xine-lib-xcb-1.12.patch
  autoreconf -vi
}

build() {
  cd ${pkgname}-${pkgver}
  ./configure --prefix=/usr --with-wavpack --disable-vdpau --with-external-dvdnav \
    --disable-optimizations
  make
}

package() {
  cd ${pkgname}-${pkgver}
  make DESTDIR="${pkgdir}" install
}