PKGBUILDs/community/python-xcffib/PKGBUILD

# Maintainer: Felix Yan <felixonmars@archlinux.org>
# Contributor: Roger Duran <rogerduran@gmail.com>

# ALARM: dequis <dx@dxzone.com.ar>
#  - remove haskell-xcffib dependency by using the pypi release instead

pkgname=python-xcffib
pkgver=0.11.0
pkgrel=1
pkgdesc="Python3 drop in replacement for xpyb, an XCB python binding"
arch=('any')
url="https://pypi.python.org/pypi/xcffib"
license=('Apache')
depends=('python-six' 'python-cffi' 'libxcb')
makedepends=('python-setuptools' 'python-cffi' 'python-six' 'libxcb')
checkdepends=('python-nose' 'xorg-server-xvfb' 'xorg-xeyes')
_name=${pkgname#python-}
source=("https://files.pythonhosted.org/packages/source/${_name::1}/$_name/$_name-$pkgver.tar.gz")
sha512sums=('22b82844295b277e2abb363ff818e7163037542ffc1ec2874a948f3b3cc63e9a8fad371fa87099910546a17f2f6f1bfb8f62214869fa30a196fc198adce14384')

prepare() {
  touch xcffib-$pkgver/test/__init__.py
}

build() {
  cd xcffib-$pkgver
  python setup.py build
}

check() {
  cd xcffib-$pkgver
  xvfb-run nosetests3
}

package() {
  cd xcffib-$pkgver
  python setup.py install --root="$pkgdir/" --optimize=1
}