PKGBUILDs/alarm/wiringx-git/PKGBUILD

# Maintainer: Paul Adams <paul@thoughtcriminal.co.uk>

buildarch=20

pkgname=('wiringx-git' 'python-wiringx-git' 'python2-wiringx-git')
pkgver=r87.6ae11ce
pkgrel=1
pkgdesc="wiringX is a modular GPIO interface, derived from wiringPi"
arch=('arm')
url="http://wiringx.org"
license=('GPL')
makedepends=('git' 'cmake' 'sed' 'python' 'python-setuptools' 'python2' 'python2-setuptools')
source=(${pkgname}::git+https://github.com/wiringX/wiringX)
md5sums=('SKIP')

pkgver() {
  cd "${pkgname}"
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
  cd "${pkgname}"
  msg2 "Removing insecure rpaths"
  sed -i 's|,-rpath=/usr/local/lib/||g' CMakeLists.txt
  cmake -DCMAKE_INSTALL_PREFIX:PATH=/usr .
}

package_wiringx-git() {
  cd "${pkgname}"
  make DESTDIR="${pkgdir}/" install
}

package_python-wiringx-git() {
  depends=('python' 'wiringx-git')
  makedepends=('python-setuptools')
  pkgdesc="Python bindings for wiringX"
  cd "${pkgbase}/python"
  python setup.py install --root="$pkgdir/" --optimize=1
}

package_python2-wiringx-git() {
  depends=('python2' 'wiringx-git')
  makedepends=('python2-setuptools')
  pkgdesc="Python2 bindings for wiringX"
  cd "${pkgbase}/python"
  python2 setup.py install --root="$pkgdir/" --optimize=1
}

# vim:set ts=2 sw=2 et: