PKGBUILDs/alarm/uboot-pandaboard/PKGBUILD

# U-Boot: Pandaboard and Pandaboard ES
# Maintainer: Kevin Mihelich <kevin@archlinuxarm.org>

buildarch=4

pkgname=uboot-pandaboard
pkgver=2013.10
pkgrel=2
pkgdesc="U-Boot for Pandaboard and Pandaboard ES"
arch=('armv7h')
url="http://git.denx.de/u-boot.git/"
license=('GPL')
makedepends=('git')
source=("uboot::git://git.denx.de/u-boot.git#tag=v${pkgver}"
        'http://raw.github.com/eewiki/u-boot-patches/master/v${pkgver}/0001-omap4_common-uEnv.txt-bootz-n-fixes.patch'
        'alarm.patch'
        'uEnv.txt')
md5sums=('SKIP'
         '683bf12be7b0be3de60cf2f33e85a011'
         '148982b955b96dfd16284181523df1a1'
         'e311fff8d388e9a8f2672cb8c5c819ac')

prepare() {
  cd uboot

  rm -rf .git
  patch -p1 -i "${srcdir}"/0001-omap4_common-uEnv.txt-bootz-n-fixes.patch
  patch -p1 -i "${srcdir}"/alarm.patch
}

build() {
  cd uboot

  unset LDFLAGS

  make distclean 
  make omap4_panda_config
  make
}

package() {
  cd uboot
  mkdir -p "${pkgdir}"/boot
  cp MLO u-boot.img "${srcdir}"/uEnv.txt "${pkgdir}"/boot
}