PKGBUILDs/extra/mono/PKGBUILD

# $Id: PKGBUILD 140778 2011-10-19 07:11:57Z daniel $
# Maintainer: Daniel Isenmann <daniel@archlinux.org>
# Contributor: Brice Carpentier <brice@dlfp.org>

# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
#  - Added alarm.patch for armv7h to fix detection of VFP capability
#    and using autogen.sh to rebuild for configure.in changes.

pkgname=mono
pkgver=3.0.7
pkgrel=1
pkgdesc="Free implementation of the .NET platform including runtime and compiler"
arch=(i686 x86_64)
license=('GPL' 'LGPL2' 'MPL' 'custom:MITX11')
url="http://www.mono-project.com/"
depends=('zlib' 'libgdiplus>=2.10' 'sh')
makedepends=('pkgconfig')
options=('!libtool' '!makeflags')
provides=('monodoc')
conflicts=('monodoc')
source=(http://download.mono-project.com/sources/${pkgname}/${pkgname}-${pkgver}.tar.bz2
        mono.binfmt.d
        alarm.patch)
md5sums=('76ebec9c97347aac13d9f28fc58b347d'
         'b9ef8a65fea497acf176cca16c1e2402'
         'db43f2824188e4d1583b676f2e62db24')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  # build mono
  if [ "$CARCH" = "armv7h" -o "$CARCH" = "armv6h" ]; then
    #Disabling alarm patch, arm support might be in now.
    #patch -Np1 -i ${srcdir}/alarm.patch
    sed -i 's/^AM_CONFIG_HEADER/AC_CONFIG_HEADERS/' configure.in
    sed -i 's/^AM_CONFIG_HEADER/AC_CONFIG_HEADERS/' eglib/configure.ac
    sed -i 's/AM_PROG_CC_STDC/AC_PROG_CC/' configure.in
    sed -i 's/AUTOMAKE_OPTIONS = cygnus//' runtime/Makefile.am
    ./autogen.sh --prefix=/usr --sysconfdir=/etc \
                 --with-fpu=VFP
  else
    sed -i 's/armv6=yes/armv6=no/' configure
    ./configure --prefix=/usr --sysconfdir=/etc 
  fi
  make

  # build jay
  cd ${srcdir}/${pkgname}-${pkgver}/mcs/jay
  make
}

package() {
  cd ${srcdir}/${pkgname}-${pkgver}
  make DESTDIR=${pkgdir} install

  # install jay
  cd ${srcdir}/${pkgname}-${pkgver}/mcs/jay
  make DESTDIR=${pkgdir} prefix=/usr INSTALL=../../install-sh install
  cd ${srcdir}/${pkgname}-${pkgver}

  # install binfmt conf file and pathes
  install -D -m644 ${srcdir}/mono.binfmt.d ${pkgdir}/usr/lib/binfmt.d/mono.conf

  #install license
  mkdir -p ${pkgdir}/usr/share/licenses/${pkgname}
  install -m644 mcs/MIT.X11 ${pkgdir}/usr/share/licenses/${pkgname}/
  
  #fix .pc file to be able to request mono on what it depends, fixes #go-oo build
  sed -i -e "s:#Requires:Requires:" ${pkgdir}/usr/lib/pkgconfig/mono.pc
}