PKGBUILDs/community/gimp-nufraw/PKGBUILD

# Maintainer: Christian Hesse <mail@eworm.de>

# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
#  - add -fsigned-char to CXXFLAGS

pkgname=gimp-nufraw
pkgver=0.42
pkgrel=5
pkgdesc='Converter for raw files; utility and GIMP plugin'
url='https://sourceforge.net/projects/nufraw/'
arch=('x86_64')
license=('GPL')
depends=('cfitsio' 'exiv2' 'gtkimageview' 'lcms2' 'lensfun' 'libjpeg-turbo')
makedepends=('gimp')
conflicts=('gimp-ufraw')
replaces=('gimp-ufraw')
optdepends=('gimp: to use the gimp import plugin for raw images')
source=("https://downloads.sourceforge.net/nufraw/nufraw-$pkgver.tar.gz" nufraw-iostream.patch nufraw-exiv2-0.27.patch)
sha256sums=('ddfb592a183618c802e990211f6efce75f4801a7708ecc364666f53af25c9f90'
            'fd0120af2cfa8783edd3d91a39b638fbb30ced8c692815be230a302bc55a71ad'
            'ec7caabbdaa8fb67097bfb72c26a1140754e184e756ec2013863af37eed67220')

prepare() {
  cd "nufraw-$pkgver"
  patch -p1 -i ../nufraw-iostream.patch # Add missing include
  patch -p1 -i ../nufraw-exiv2-0.27.patch # Fix build with exiv2 0.27 (Gentoo)

  autoreconf -fi

  mv nufraw.desktop{.desktop,}
  chmod +x generate_schemas.sh
}

build() {
  cd "nufraw-$pkgver"

  CXXFLAGS+=" -fsigned-char"

  ./configure \
    --prefix=/usr \
    --enable-extras \
    --enable-mime \
    --enable-openmp \
    --with-gimp \
    --with-cinepaint \
    --enable-contrast
  make
}

package() {
  make -C "nufraw-$pkgver" DESTDIR="$pkgdir" install
  rm -f "$pkgdir/usr/bin/dcraw"
}