PKGBUILDs/core/libgcrypt/PKGBUILD

# $Id$
# Maintainer: Andreas Radke <andyrtr@archlinux.org>

# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
#  - disable NEON and ARMv8 crypto support on !AArch64

pkgname=libgcrypt
pkgver=1.7.8
pkgrel=1
pkgdesc="General purpose cryptographic library based on the code from GnuPG"
arch=(i686 x86_64)
url="http://www.gnupg.org"
license=('LGPL')
depends=('libgpg-error')
options=('!emptydirs')
# https://www.gnupg.org/download/integrity_check.html
source=(ftp://ftp.gnupg.org/gcrypt/${pkgname}/${pkgname}-${pkgver}.tar.bz2{,.sig})
# https://gnupg.org/download/integrity_check.html
sha1sums=('65a4a495aa858483e66868199eaa8238572ca6cd'
          'SKIP')
validpgpkeys=('031EC2536E580D8EA286A9F22071B08A33BD3F06' # "NIIBE Yutaka (GnuPG Release Key) <gniibe@fsij.org>"
              'D8692123C4065DEA5E0F3AB5249B39D24F25E3B6') # Werner Koch

build() {
  cd ${pkgname}-${pkgver}

  [[ $CARCH != "aarch64" ]] && CONFIG="--disable-neon-support --disable-arm-crypto-support"

  ./configure --prefix=/usr \
	--disable-static \
	--disable-padlock-support \
	$CONFIG
  make
}

check() {
  cd ${pkgname}-${pkgver}
  make check
}

package() {
  cd ${pkgname}-${pkgver}
  make DESTDIR=${pkgdir} install
}