mirror of
https://github.com/archlinuxarm/PKGBUILDs.git
synced 2024-11-18 22:54:00 +00:00
81 lines
3.8 KiB
Bash
81 lines
3.8 KiB
Bash
|
# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
|
||
|
|
# Maintainer: Eric Bélanger <eric@archlinux.org>
|
||
|
|
|
||
|
|
# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
|
||
|
|
# - upstream patch for AArch64
|
||
|
|
|
||
|
|
pkgbase=avidemux
|
||
|
|
pkgname=('avidemux-cli' 'avidemux-qt')
|
||
|
|
pkgver=2.7.4
|
||
|
|
pkgrel=3
|
||
|
|
pkgdesc='Graphical tool to edit video (filter/re-encode/split)'
|
||
|
|
url='http://fixounet.free.fr/avidemux/'
|
||
|
|
arch=('x86_64')
|
||
|
|
license=('GPL2')
|
||
|
|
makedepends=('cmake' 'libxslt' 'qt5-base' 'jack' 'libvorbis' 'libxv' 'opus' 'desktop-file-utils'
|
||
|
|
'alsa-lib' 'lame' 'xvidcore' 'faad2' 'faac' 'x264' 'x265' 'libsamplerate'
|
||
|
|
'opencore-amr' 'yasm' 'mesa' 'libvpx' 'libpulse' 'libva' 'intltool' 'sqlite'
|
||
|
|
'libvdpau' 'libdca' 'fribidi' 'glu' 'qt5-tools' 'twolame' 'libfdk-aac' 'libass')
|
||
|
|
options=('!emptydirs')
|
||
|
|
source=(https://downloads.sourceforge.net/avidemux/avidemux_${pkgver}.tar.gz
|
||
|
|
https://github.com/mean00/avidemux2/commit/aac9d5f795ea0af1e8fd54613d7e4c2fdad343bd.patch)
|
||
|
|
sha256sums=('7db0ac01c8255279a2c360ecb2725c27ea8a2c5bd1f38aeafabfed33ea588da9'
|
||
|
|
'4c3a6653c238394f4df1a50c4431f5be702f2fa01820e78efecc31710b5b00ab')
|
||
|
|
sha512sums=('e6d0a9eb525d82d0bdecb41b50eaa5894134064148a1889e4bba704d512bb53f871f797444668a0601fecf4e0e61a1f1727b1c59d543860bb64c1a294eb9bf42'
|
||
|
|
'bf4245064f4b082fe12e3baa12261836e8aff81eafcd18f582f9fb258ab45f037434619b4e42e4aac2141f9f7811ce2beb43e38e3c42e9abcfed8e50984954bb')
|
||
|
|
|
||
|
|
prepare() {
|
||
|
|
cd ${pkgbase}_${pkgver}
|
||
|
|
sed -i 's|../avidemux/qt4|../avidemux/qt4 -DLRELEASE_EXECUTABLE=/usr/bin/lrelease-qt5|' bootStrap.bash
|
||
|
|
sed -e 's|0.19|1.0|' -i avidemux_plugins/ADM_videoFilters6/ass/CMakeLists.txt
|
||
|
|
patch -p1 -i ../aac9d5f795ea0af1e8fd54613d7e4c2fdad343bd.patch
|
||
|
|
}
|
||
|
|
|
||
|
|
build() {
|
||
|
|
cd ${pkgbase}_${pkgver}
|
||
|
|
bash bootStrap.bash --with-core --with-cli --with-plugins
|
||
|
|
}
|
||
|
|
|
||
|
|
package_avidemux-cli() {
|
||
|
|
depends=('libxml2' 'fontconfig' 'sqlite' 'libvpx' 'libva' 'libvdpau')
|
||
|
|
optdepends=('lame: for the corresponding audio encoder plugin'
|
||
|
|
'faac: for the corresponding audio encoder plugin'
|
||
|
|
'faad2: for the corresponding audio decoder plugin'
|
||
|
|
'opus: for the corresponding audio decoder plugin'
|
||
|
|
'opencore-amr: for the corresponding audio decoder plugin'
|
||
|
|
'jack: for the corresponding audio device plugin'
|
||
|
|
'libpulse: for the corresponding audio device plugin'
|
||
|
|
'x264: for the corresponding video encoder plugin'
|
||
|
|
'libx264: for the corresponding video encoder plugin'
|
||
|
|
'x265: for the corresponding video encoder plugin'
|
||
|
|
'xvidcore: for the corresponding video encoder plugin'
|
||
|
|
'qt5-base: for the QtScript scripting support'
|
||
|
|
'libdca: for the corresponding audio decoder plugin'
|
||
|
|
'libfdk-aac: for the corresponding audio decoder plugin'
|
||
|
|
'twolame: for the corresponding audio decoder plugin'
|
||
|
|
'libass: for the corresponding video filter plugin'
|
||
|
|
'fribidi: for the corresponding video filter plugin')
|
||
|
|
|
||
|
|
cd ${pkgbase}_${pkgver}
|
||
|
|
make -C buildCli DESTDIR="${pkgdir}" install
|
||
|
|
make -C buildCore DESTDIR="${pkgdir}" install
|
||
|
|
make -C buildPluginsCLI DESTDIR="${pkgdir}" install
|
||
|
|
make -C buildPluginsCommon DESTDIR="${pkgdir}" install
|
||
|
|
|
||
|
|
install -Dm 644 avidemux_icon.png "${pkgdir}/usr/share/pixmaps/avidemux.png"
|
||
|
|
install -Dm 644 man/avidemux.1 -t "${pkgdir}/usr/share/man/man1"
|
||
|
|
}
|
||
|
|
|
||
|
|
package_avidemux-qt() {
|
||
|
|
pkgdesc='Graphical tool to edit video (filter/re-encode/split) - Qt GUI'
|
||
|
|
depends=("avidemux-cli=${pkgver}" 'qt5-base' 'x264' 'x265' 'glu' 'libxv' 'desktop-file-utils')
|
||
|
|
replaces=('avidemux-gtk')
|
||
|
|
|
||
|
|
cd ${pkgbase}_${pkgver}
|
||
|
|
make -C buildQt5 DESTDIR="${pkgdir}" install
|
||
|
|
make -C buildPluginsQt5 DESTDIR="${pkgdir}" install
|
||
|
|
#install -Dm 644 avidemux-qt.desktop -t "${pkgdir}/usr/share/applications"
|
||
|
|
}
|
||
|
|
|
||
|
|
# vim: ts=2 sw=2 et:
|