PKGBUILDs/community/gendesk/PKGBUILD

# $Id$
# Maintainer: Alexander F Rødseth <xyproto@archlinux.org>

# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
#  - !strip option, stripped binary fails under ARM

pkgname=gendesk
pkgver=0.6.5
pkgrel=1
pkgdesc='Utility for generating desktop files'
arch=('x86_64' 'i686')
url='http://gendesk.roboticoverlords.org/'
license=('MIT')
makedepends=('gcc-go' 'git' 'mercurial')
depends=('glibc')
options=('!strip')
source=("http://roboticoverlords.org/$pkgname/$pkgname-$pkgver.tar.xz"{,.asc}
        'http://roboticoverlords.org/images/default.png')
validpgpkeys=('962855F072C7A01846405864FCF3C8CB5CF9C8D4')
sha256sums=('f68a3ae07c7a209b38c0c386c4130ba4faf7b454ab427242e5fc229af8164e9b'
            'SKIP'
            '4d96eded48e536d02e35727c36dc20844c2e44654e81baf78e10aee4eb48e837')

prepare() {
  cd "$pkgname-$pkgver"

  GOPATH=`pwd` go get -d -v
}

build() {
  cd "$pkgname-$pkgver"

  GOPATH=`pwd` go build
}

package() {
  cd "$pkgname-$pkgver"

  install -Dm755 "$pkgname-$pkgver" "$pkgdir/usr/bin/$pkgname"
  install -Dm644 "$srcdir/default.png" "$pkgdir/usr/share/pixmaps/default.png"
  install -Dm644 "$pkgname.1.gz" "$pkgdir/usr/share/man/man1/$pkgname.1.gz"
  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}

# vim: ts=2 sw=2 et: