PKGBUILDs/alarm/rpi-eeprom/PKGBUILD

# Maintainer: graysky <graysky@archlinux.us>

pkgname=rpi-eeprom
_commit=7deaaa181a5f6b263e006eb9ea3758731a943125
pkgver=20220209
pkgrel=1
pkgdesc="Bootloader and VL805 USB controller EEPROM update tool for RPi4"
arch=('any')
url='https://github.com/raspberrypi/rpi-eeprom'
license=('custom')
depends=(python pciutils raspberrypi-firmware coreutils binutils)
backup=("etc/default/$pkgname-update")
source=("$pkgname-$pkgver-${_commit:0:10}.tar.gz::https://github.com/raspberrypi/rpi-eeprom/archive/$_commit.tar.gz")
md5sums=('23406d14238f9980231a4b04256b3ab2')
install="$pkgname.install"

package() {
  cd "$pkgname-$_commit"
  install -pd "$pkgdir/usr/bin"
  install -pm755 rpi-eeprom-config "$pkgdir/usr/bin/rpi-eeprom-config"
  install -pm755 rpi-eeprom-digest "$pkgdir/usr/bin/rpi-eeprom-digest"
  install -pm755 rpi-eeprom-update "$pkgdir/usr/bin/rpi-eeprom-update"
  install -pDm644 "$pkgname-update-default" "$pkgdir/etc/default/$pkgname-update"

  # Arch ARM does not ship raspi-config
  sed -i '/to change the release/d' "$pkgdir/usr/bin/rpi-eeprom-update"

  install -pd "$pkgdir/usr/lib/firmware/raspberrypi/bootloader/backup"
  for target in beta critical stable; do
    cp -a "firmware/$target" "$pkgdir/usr/lib/firmware/raspberrypi/bootloader"
  done
  ln -sf critical "$pkgdir/usr/lib/firmware/raspberrypi/bootloader/default"
  ln -sf stable "$pkgdir/usr/lib/firmware/raspberrypi/bootloader/latest"

  install -pDm644 LICENSE "$pkgdir/usr/share/doc/$pkgname"

  # firmware files should not be executable
  find "$pkgdir/usr/lib/firmware/raspberrypi/bootloader" -name '*.bin' -exec chmod 644 '{}' +
}