mirror of
https://github.com/archlinuxarm/PKGBUILDs.git
synced 2024-11-08 22:45:43 +00:00
61 lines
2 KiB
Bash
61 lines
2 KiB
Bash
|
# Maintainer: Tobias Powalowski <tpowa@archlinux.org>
|
||
|
|
# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
|
||
|
|
# Contributor: judd <jvinet@zeroflux.org>
|
||
|
|
|
||
|
|
# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
|
||
|
|
# - upstream patch to fix FTBFS
|
||
|
|
|
||
|
|
pkgname=pam
|
||
|
|
pkgver=1.6.0
|
||
|
|
pkgrel=3
|
||
|
|
pkgdesc="PAM (Pluggable Authentication Modules) library"
|
||
|
|
arch=('x86_64')
|
||
|
|
license=('GPL2')
|
||
|
|
url="http://linux-pam.org"
|
||
|
|
depends=('glibc' 'libtirpc' 'pambase' 'audit' 'libaudit.so' 'libxcrypt' 'libcrypt.so')
|
||
|
|
makedepends=('flex' 'w3m' 'docbook-xml>=4.4' 'docbook-xsl')
|
||
|
|
provides=('libpam.so' 'libpamc.so' 'libpam_misc.so')
|
||
|
|
backup=(etc/security/{access.conf,faillock.conf,group.conf,limits.conf,namespace.conf,namespace.init,pwhistory.conf,pam_env.conf,time.conf} etc/environment)
|
||
|
|
source=(https://github.com/linux-pam/linux-pam/releases/download/v$pkgver/Linux-PAM-$pkgver{,-docs}.tar.xz{,.asc}
|
||
|
|
https://github.com/linux-pam/linux-pam/commit/cc9d40b7cdbd3e15ccaa324a0dda1680ef9dea13.patch
|
||
|
|
$pkgname.tmpfiles)
|
||
|
|
validpgpkeys=(
|
||
|
|
'8C6BFD92EE0F42EDF91A6A736D1A7F052E5924BB' # Thorsten Kukuk
|
||
|
|
'296D6F29A020808E8717A8842DB5BD89A340AEB7' #Dimitry V. Levin <ldv@altlinux.org>
|
||
|
|
)
|
||
|
|
|
||
|
|
sha256sums=('fff4a34e5bbee77e2e8f1992f27631e2329bcbf8a0563ddeb5c3389b4e3169ad'
|
||
|
|
'SKIP'
|
||
|
|
'3e82730d3350795c42f3708f6609a92c1df841d518aa17c28fd702fe5ec23a32'
|
||
|
|
'SKIP'
|
||
|
|
'6a0dbd7cb38680143e327d87a9c52f8ac9e8910d30208fd56c0560927c5b9ab7'
|
||
|
|
'5631f224e90c4f0459361c2a5b250112e3a91ba849754bb6f67d69d683a2e5ac')
|
||
|
|
|
||
|
|
options=('!emptydirs')
|
||
|
|
|
||
|
|
prepare() {
|
||
|
|
cd Linux-PAM-$pkgver
|
||
|
|
patch -p1 -i ../cc9d40b7cdbd3e15ccaa324a0dda1680ef9dea13.patch
|
||
|
|
}
|
||
|
|
|
||
|
|
build() {
|
||
|
|
cd Linux-PAM-$pkgver
|
||
|
|
./configure \
|
||
|
|
--libdir=/usr/lib \
|
||
|
|
--sbindir=/usr/bin \
|
||
|
|
--enable-logind \
|
||
|
|
--disable-db
|
||
|
|
make
|
||
|
|
}
|
||
|
|
|
||
|
|
package() {
|
||
|
|
install -Dm 644 $pkgname.tmpfiles "$pkgdir"/usr/lib/tmpfiles.d/$pkgname.conf
|
||
|
|
cd Linux-PAM-$pkgver
|
||
|
|
make DESTDIR="$pkgdir" SCONFIGDIR=/etc/security install
|
||
|
|
|
||
|
|
# set unix_chkpwd uid
|
||
|
|
chmod +s "$pkgdir"/usr/bin/unix_chkpwd
|
||
|
|
}
|
||
|
|
|
||
|
|
# vim: ts=2 sw=2 et:
|