PKGBUILDs/extra/efl/PKGBUILD

# $Id$
# Maintainer: Ronald van Haren <ronald@archlinux.org>
# Contributor: Enlightenment Developers <enlightenment-devel@enlightenment.org>

# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
#  - configure with --disable-neon for !aarch64
#  - configure with --enable-lua-old for aarch64

pkgbase=efl
pkgname=('efl' 'efl-docs')
pkgver=1.18.4
pkgrel=2
pkgdesc="Enlightenment Foundation Libraries"
arch=('i686' 'x86_64')
url="https://www.enlightenment.org"
license=('BSD' 'LGPL2.1' 'GPL2' 'custom')
depends=('bullet' 'libjpeg-turbo' 'gst-plugins-base'
         'luajit' 'curl' 'fribidi' 'libpulse' 'libxcomposite'
         'libxinerama' 'libxrandr' 'libxss' 'libinput'
         'libxcursor' 'libxp' 'libwebp' 'shared-mime-info'
         'libxkbcommon' 'wayland' 'lz4' 'openjpeg' 'avahi'
         'libspectre' 'libraw' 'librsvg')
optdepends=('python2: einabench-cmp' 'libreoffice: thumbnailing for DOC/PPT/XLS files')
makedepends=('doxygen' 'python' 'texlive-core' 'ghostscript' 'imagemagick')
options=('!emptydirs')
source=(https://download.enlightenment.org/rel/libs/${pkgname}/$pkgname-$pkgver.tar.xz
        eina_doxygen.patch
        efl-1.18.2-openssl-1.1.patch)
sha256sums=('39ebc07e37437d6ecdeb0f645783484e28a882b38f7e619ad12c2bf9b5548025'
            '2a83b636a4e897ea9445b42de98dbf8514a920c3765648b0c27f7366ad95cb87'
            'fa8e9d0b4f8ec36a40354f2c7c3e2bef055ab7301317437e3a6c5fd01152e9c3')

prepare() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  sed -i 's/env python$/&2/' src/scripts/eina/eina-bench-cmp

  # fix docs building
  patch -Np0 -i ${srcdir}/eina_doxygen.patch

  patch -Np1 -i ../efl-1.18.2-openssl-1.1.patch
}

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  export CFLAGS="$CFLAGS -fvisibility=hidden"

  [[ $CARCH == "aarch64" ]] && CONFIG="--enable-lua-old"
  [[ $CARCH != "aarch64" ]] && CONFIG="--disable-neon"

  ./configure --prefix=/usr \
  --disable-static --disable-tslib --enable-fb \
  --enable-xinput22 --enable-multisense --enable-systemd \
  --enable-image-loader-webp --enable-harfbuzz --enable-wayland \
  --enable-liblz4 --enable-drm --enable-elput --enable-egl --with-opengl=es $CONFIG

  make
  make -j1 doc || return 0  # don't fail on the docs
}

package_efl(){
  replaces=('elementary' 'evas_generic_loaders' 'emotion_generic_players')

  cd "${srcdir}/${pkgname}-${pkgver}"
  make -j1 DESTDIR=${pkgdir} install

  # install non-standard license files
  install -Dm644 "${srcdir}/${pkgname}-${pkgver}/licenses/COPYING.BSD" \
    "${pkgdir}/usr/share/licenses/${pkgname}/COPYING.BSD"
  install -Dm644 "${srcdir}/${pkgname}-${pkgver}/licenses/COPYING.SMALL" \
    "${pkgdir}/usr/share/licenses/${pkgname}/COPYING.SMALL"
}

package_efl-docs() {
  pkgdesc="Documentation for the Enlightenment Foundation Libraries"
  depends=()

  cd "${srcdir}/${pkgbase}-${pkgver}"
  install -d "${pkgdir}/usr/share/doc/${pkgbase}"
  cp -a doc/html "${pkgdir}/usr/share/doc/${pkgbase}/html"
  cp -a doc/latex "${pkgdir}/usr/share/doc/${pkgbase}/latex"
}