PKGBUILDs/extra/haveged/PKGBUILD

# $Id$
# Maintainer:  Christian Hesse <mail@eworm.de>
# Contributor: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
# Contributor: kfgz <kfgz at interia dot pl>
# Contributor: pootzko <pootzko at gmail dot com>

# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
#  - patch from Alpine Linux to fix cache detection issues on ARM

pkgname=haveged
pkgver=1.9.3
pkgrel=1
pkgdesc='Entropy harvesting daemon using CPU timings'
arch=('x86_64')
url='https://github.com/jirka-h/haveged'
license=('GPL')
depends=('glibc')
validpgpkeys=('8F6B7293B03E5AC5762B65CE2E2F252B05CCA168') # Jirka Hladky <hladky.jiri@gmail.com>
source=("$pkgname-$pkgver.tar.gz::https://github.com/jirka-h/$pkgname/archive/$pkgver.tar.gz"
        "https://github.com/jirka-h/$pkgname/releases/download/$pkgver/$pkgname-$pkgver.tar.gz.asc"
        'haveged.service'
        'fix-cpu-cache-size-detection.patch')
sha256sums=('f402d256cffba5c644f3396df7c2d65c908e5aae0985efafbc412bb3395df241'
            'SKIP'
            '7cb5d21d075650ad8f08f0ba958cc1bc39b5ff67ef484d9fce365febcaecb05c'
            '5aecfd72a1dbb9cc9b32d5677917d8a59dba7a2e021e31dee95f3f5b9e7ecf28')

prepare() {
  cd $pkgname-$pkgver

  patch -p1 -i ../fix-cpu-cache-size-detection.patch
}

build() {
  cd $pkgname-$pkgver

  ./configure \
      --prefix=/usr \
      --bindir=/usr/bin \
      --sbindir=/usr/bin
  make
}

package() {
  cd $pkgname-$pkgver

  make DESTDIR="$pkgdir" install

  install -D -m0644 "${srcdir}"/haveged.service "$pkgdir"/usr/lib/systemd/system/haveged.service
}