PKGBUILDs/extra/clisp/PKGBUILD

# $Id$
# Maintainer: Juergen Hoetzel <juergen@archlinux.org>

# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
#  - patch to fix ARM assembly
#  - ulimit change to fix segfaults

pkgname=clisp
pkgver=2.49
pkgrel=6
pkgdesc="ANSI Common Lisp interpreter, compiler and debugger"
arch=('i686' 'x86_64')
license=('GPL')
url="http://clisp.cons.org/"
depends=('readline' 'libsigsegv')
provides=('common-lisp')
makedepends=('ffcall')
options=('!makeflags' '!emptydirs')
source=("http://downloads.sourceforge.net/sourceforge/clisp/clisp-${pkgver}.tar.bz2"
        'clisp-gcc5.patch'
        "patch-modules_readline_readline.lisp"
        'clisp-arm.patch')
md5sums=('1962b99d5e530390ec3829236d168649'
         'e3008f96f6cd3059717d4a930b8c0e9c'
         '5b29c9301ab7c1b683da70c2f805609f'
         'f52b37840eaae76410f14f1adc8a00e2')

prepare() {
  cd $srcdir/${pkgname}-${pkgver}
  patch -Np1 -i ../clisp-gcc5.patch
  patch -Np0 -i ../patch-modules_readline_readline.lisp
  patch -p0 -i ../clisp-arm.patch
  ulimit -s unlimited

  # https://sourceforge.net/p/clisp/clisp/ci/cebd289dfc19de4aa504113dfcb0284657787430/
  # http://hg.slitaz.org/wok/rev/d5a39f30f9f1#l2.28
  sed -i 's/clisp\.cons\.org/clisp.org/' src/cfgunix.lisp
}

build() {
  cd $srcdir/${pkgname}-${pkgver}
  ./configure --prefix=/usr --with-readline --with-ffcall src
  cd src
  ./makemake --prefix=/usr --with-readline --with-ffcall --with-dynamic-ffi > Makefile
  make
  sed -i 's,http://www.lisp.org/HyperSpec/,http://www.lispworks.com/reference/HyperSpec/,g' config.lisp
  make
}

check() {
  cd $srcdir/${pkgname}-${pkgver}/src
  make check
}

package() {
  cd $srcdir/${pkgname}-${pkgver}/src
  make DESTDIR=$pkgdir install
}