PKGBUILDs/core/keyutils/PKGBUILD

# $Id: PKGBUILD 144589 2011-12-07 12:54:44Z stephane $
# Maintainer: Stéphane Gaudreault <stephane@archlinux.org>
# Contributor: Tobias Powalowski <tpowa@archlinux.org>

# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
#  - commented out sed line, doesn't build otherwise
#  - must build -j1, everything must build in order

pkgname=keyutils
pkgver=1.5.5
pkgrel=3
pkgdesc="Linux Key Management Utilities"
arch=(i686 x86_64)
url="http://www.kernel.org"
license=('GPL2' 'LGPL2.1')
depends=('glibc' 'sh')
backup=(etc/request-key.conf)
source=(http://people.redhat.com/~dhowells/${pkgname}/${pkgname}-${pkgver}.tar.bz2)
md5sums=('d759680b2f23c99af95938f5026f25fb')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  #sed -i "s|/lib64|/lib|g" Makefile
  make -j1 CFLAGS="${CFLAGS}" LDFLAGS="${LDFLAGS}"
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" LIBDIR="/usr/lib" USRLIBDIR="/usr/lib" install
  # add nfsidmap to config file #30396
  echo "# NFS idmap resolver" >> $pkgdir/etc/request-key.conf
  echo "create id_resolver * * /usr/sbin/nfsidmap %k %d" \
       >> $pkgdir/etc/request-key.conf
}