mirror of
https://github.com/archlinuxarm/PKGBUILDs.git
synced 2024-11-28 22:57:37 +00:00
43 lines
1.4 KiB
Bash
43 lines
1.4 KiB
Bash
|
# Maintainer: Daniel Bermond <dbermond@archlinux.org>
|
||
|
|
# Maintainer: Bruno Pagani <archange@archlinux.org>
|
||
|
|
|
||
|
|
# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
|
||
|
|
# - make llvm-spirv, install doesn't work otherwise
|
||
|
|
|
||
|
|
_srcname=SPIRV-LLVM-Translator
|
||
|
|
pkgname=${_srcname,,}
|
||
|
|
pkgver=12.0.0
|
||
|
|
pkgrel=1
|
||
|
|
pkgdesc="Tool and a library for bi-directional translation between SPIR-V and LLVM IR"
|
||
|
|
arch=(x86_64)
|
||
|
|
url="https://github.com/KhronosGroup/SPIRV-LLVM-Translator/"
|
||
|
|
license=(custom)
|
||
|
|
depends=(llvm-libs)
|
||
|
|
makedepends=(cmake llvm spirv-tools)
|
||
|
|
checkdepends=(python python-setuptools clang)
|
||
|
|
source=(${url}/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz)
|
||
|
|
sha256sums=('6e4fad04203f25fcde4c308c53e9f59bd05a390978992db3212d4b63aff62108')
|
||
|
|
|
||
|
|
build() {
|
||
|
|
cmake -B build -S ${_srcname}-${pkgver} \
|
||
|
|
-DBUILD_SHARED_LIBS=ON \
|
||
|
|
-DCMAKE_BUILD_TYPE=Release \
|
||
|
|
-DCMAKE_INSTALL_PREFIX=/usr \
|
||
|
|
-DCMAKE_POSITION_INDEPENDENT_CODE=ON \
|
||
|
|
-DCMAKE_SKIP_RPATH=ON \
|
||
|
|
-DLLVM_INCLUDE_TESTS=ON \
|
||
|
|
-DLLVM_EXTERNAL_LIT=/usr/bin/lit \
|
||
|
|
-Wno-dev
|
||
|
|
make -C build llvm-spirv
|
||
|
|
}
|
||
|
|
|
||
|
|
check() {
|
||
|
|
LD_LIBRARY_PATH="${srcdir}/build/lib/SPIRV" make -C build test
|
||
|
|
}
|
||
|
|
|
||
|
|
package() {
|
||
|
|
make -C build DESTDIR="${pkgdir}" install
|
||
|
|
install -Dm755 build/tools/llvm-spirv/llvm-spirv -t "${pkgdir}"/usr/bin
|
||
|
|
install -Dm644 ${_srcname}-${pkgver}/LICENSE.TXT -t "${pkgdir}"/usr/share/licenses/${pkgname}/
|
||
|
|
}
|