PKGBUILDs/extra/kauth/PKGBUILD

# $Id$
# Maintainer: Felix Yan <felixonmars@archlinux.org>
# Contributor: Andrea Scarpino <andrea@archlinux.org>

# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
#  - drop clang makedepend, FTBFS on AArch64

pkgname=kauth
pkgver=5.33.0
pkgrel=2
pkgdesc='Abstraction to system policy and authentication features'
arch=('i686' 'x86_64')
url='https://community.kde.org/Frameworks'
license=('LGPL')
depends=('kcoreaddons' 'polkit-qt5')
makedepends=('extra-cmake-modules' 'qt5-tools' 'python-pyqt5' 'python2-pyqt5')
optdepends=('python-pykf5: to use the Python 3 bindings' 'python2-pykf5: to use the Python 2 bindings')
groups=('kf5')
source=("https://download.kde.org/stable/frameworks/${pkgver%.*}/${pkgname}-${pkgver}.tar.xz"{,.sig}
        CVE-2017-8422.patch::"https://cgit.kde.org/kauth.git/patch/?id=df875f72")
sha256sums=('c7a77c00cc4f09d8cea32d953718db5b841ed2454e8e6df04035b1270927d1d1'
            'SKIP'
            'dd628d4ff775a3444bcb382f6dfc6fa0df4583690f2200ddb256275e5a94d4b4')
validpgpkeys=(53E6B47B45CEA3E0D5B7457758D0EE648A48B3BB) # David Faure <faure@kde.org>

prepare() {
  mkdir -p build

# Fix CVE-2017-8422
  cd $pkgname-$pkgver
  patch -p1 -i ../CVE-2017-8422.patch 
}

build() {
  cd build
  cmake ../${pkgname}-${pkgver} \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DKDE_INSTALL_LIBDIR=lib \
    -DKDE_INSTALL_LIBEXECDIR=lib \
    -DBUILD_TESTING=OFF
  make
}

package() {
  cd build
  make DESTDIR="${pkgdir}" install
}