PKGBUILDs/extra/libjpeg-turbo/PKGBUILD

# $Id$
# Maintainer: Gaetan Bisson <bisson@archlinux.org>
# Contributor: Allan McRae <allan@archlinux.org>
# Contributor: Simone Sclavi 'Ito' <darkhado@gmail.com>

# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
#  - removed makedepends on nasm
#  - added --without-simd to configure, no NEON

pkgname=libjpeg-turbo
pkgver=1.3.1
pkgrel=3
pkgdesc='JPEG image codec with accelerated baseline compression and decompression'
url='http://libjpeg-turbo.virtualgl.org/'
license=('GPL' 'custom')
arch=('i686' 'x86_64')
source=("http://downloads.sourceforge.net/project/${pkgname}/${pkgver}/${pkgname}-${pkgver}.tar.gz"
        'jstdhuff.patch'
        'overrun.patch')
sha1sums=('5fa19252e5ca992cfa40446a0210ceff55fbe468'
          'f459890257df430dc4e2d8bd3060173a1be7516e'
          '438aba2241b19857bab090c6f61bd3f249f27591')
provides=('libjpeg=8.0.2' 'turbojpeg')
conflicts=('libjpeg' 'turbojpeg')
replaces=('libjpeg' 'turbojpeg')

prepare() {
	cd "${srcdir}/${pkgname}-${pkgver}"
	patch -p0 -i ../jstdhuff.patch # FS#42747
	patch -p1 -i ../overrun.patch # FS#42922
}

build() {
	cd "${srcdir}/${pkgname}-${pkgver}"
	./configure --prefix=/usr --with-jpeg8 --mandir=/usr/share/man --without-simd
	make
}

check() {
	cd "${srcdir}/${pkgname}-${pkgver}"
	make test
}

package() {
	cd "${srcdir}/${pkgname}-${pkgver}"
	make \
		DESTDIR="${pkgdir}" \
		docdir="/usr/share/doc/${pkgname}" \
		exampledir="/usr/share/doc/${pkgname}" \
		install
	
	install -d "${pkgdir}/usr/share/licenses/libjpeg-turbo"
	ln -t "${pkgdir}/usr/share/licenses/libjpeg-turbo" -s ../../doc/libjpeg-turbo/README{,-turbo.txt}
	install -m644 jpegint.h "${pkgdir}/usr/include" # required by other software
}