PKGBUILDs/extra/cln/PKGBUILD

# Maintainer: Eric Bélanger <eric@archlinux.org>

# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
#  - Redefined our CFLAGS and CXXFLAGS to remove -O2, and define -DNO_ASM.
#    Optimization kills the builds, NO_ASM prevents it using asm that doesn't work for us.
#  - Removed building and installing pdf docs, it always fails.

pkgname=cln
pkgver=1.3.6
pkgrel=2
pkgdesc="Class library for numbers"
arch=('x86_64')
url="https://www.ginac.de/CLN/"
license=('GPL')
depends=('gmp')
makedepends=('texlive-core')
source=(https://www.ginac.de/CLN/${pkgname}-${pkgver}.tar.bz2)
sha1sums=('144f15a57f4b25ada0f10ff28458de03578f6f16')

build() {
  cd ${pkgname}-${pkgver}
  if [ "$CARCH" = "aarch64" ]; then
    export CFLAGS="-march=armv8-a -pipe -DNO_ASM"
    export CXXFLAGS="-march=armv8-a -pipe -DNO_ASM"
  elif [ "$CARCH" = "armv7h" ]; then
    export CFLAGS="-march=armv7-a -mfloat-abi=hard -mfpu=vfpv3-d16 -pipe -DNO_ASM"
    export CXXFLAGS="-march=armv7-a -mfloat-abi=hard -mfpu=vfpv3-d16 -pipe -DNO_ASM"
  elif [ "$CARCH" = "armv6h" ]; then
    export CFLAGS="-march=armv6 -mfloat-abi=hard -mfpu=vfp -pipe -DNO_ASM"
    export CXXFLAGS="-march=armv6 -mfloat-abi=hard -mfpu=vfp -pipe -DNO_ASM"
  else
    export CFLAGS="-march=armv5te -pipe -DNO_ASM"
    export CXXFLAGS="-march=armv5te -pipe -DNO_ASM"
  fi
  ./configure --prefix=/usr
  make all html
}

check() {
  cd ${pkgname}-${pkgver}
  make check
}

package() {
  cd ${pkgname}-${pkgver}
  make DESTDIR="${pkgdir}" install install-html
}