PKGBUILDs/extra/libvorbis/PKGBUILD

# Maintainer: Tobias Kieslich <tobias@archlinux.org>
# Contributor: dorphell <dorphell@archlinux.org>
# Contributor: John Proctor <jproctor@prium.net>

# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
#  - remove Arch's CFLAGS replacement, doesn't work with our flags

plugrel=1

pkgname=libvorbis
pkgver=1.3.3
pkgrel=1
pkgdesc="Vorbis codec library"
arch=('i686' 'x86_64')
license=('BSD')
url="http://www.xiph.org/vorbis/"
depends=('libogg')
options=('!libtool')
source=(http://downloads.xiph.org/releases/vorbis/${pkgname}-${pkgver}.tar.gz)
md5sums=('6b1a36f0d72332fae5130688e65efe1f')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  #-march=i686 optimizes too much, strip it out
  #CFLAGS=${CFLAGS/-march=$CARCH} ./configure --prefix=/usr --disable-static
  LIBS+="-lm" ./configure --prefix=/usr --disable-static
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
  install -Dm644 COPYING "${pkgdir}/usr/share/licenses/$pkgname/LICENSE"
}