From 00903fe13e4e8a1ecb72cc94e79725862fca589a Mon Sep 17 00:00:00 2001
From: Kevin Mihelich <kevin@archlinuxarm.org>
Date: Thu, 17 Feb 2022 13:51:30 +0000
Subject: [PATCH] removed extra/pipewire

---
 extra/pipewire/PKGBUILD                       | 224 ------------------
 extra/pipewire/pipewire-media-session.install |  25 --
 extra/pipewire/pipewire-pulse.install         |  14 --
 extra/pipewire/pipewire.install               |  14 --
 4 files changed, 277 deletions(-)
 delete mode 100644 extra/pipewire/PKGBUILD
 delete mode 100644 extra/pipewire/pipewire-media-session.install
 delete mode 100644 extra/pipewire/pipewire-pulse.install
 delete mode 100644 extra/pipewire/pipewire.install

diff --git a/extra/pipewire/PKGBUILD b/extra/pipewire/PKGBUILD
deleted file mode 100644
index 55128e492..000000000
--- a/extra/pipewire/PKGBUILD
+++ /dev/null
@@ -1,224 +0,0 @@
-# Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
-# Maintainer: David Runge <dvzrv@archlinux.org>
-# Contributor: Jan de Groot <jgc@archlinux.org>
-
-# remove when bumped upstream
-
-pkgbase=pipewire
-pkgname=(pipewire alsa-card-profiles pipewire-docs pipewire-alsa pipewire-jack
-         pipewire-pulse gst-plugin-pipewire pipewire-zeroconf pipewire-v4l2 pipewire-x11-bell)
-pkgver=0.3.45
-pkgrel=1.1
-epoch=1
-pkgdesc="Low-latency audio/video router and processor"
-url="https://pipewire.org"
-license=(MIT)
-arch=(x86_64)
-makedepends=(git meson doxygen graphviz python-docutils valgrind libpulse
-             alsa-lib libusb gst-plugins-base rtkit dbus sdl2 ncurses libcanberra libsndfile
-             bluez-libs sbc libldac libfreeaptx libfdk-aac avahi lilv
-             webrtc-audio-processing)
-checkdepends=(desktop-file-utils)
-options=(debug)
-_commit=bdd407fe66cc9e46d4bc4dcc989d50679000482b  # tags/0.3.45
-source=("git+https://gitlab.freedesktop.org/pipewire/pipewire.git#commit=$_commit")
-sha256sums=('SKIP')
-
-pkgver() {
-  cd pipewire
-  git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
-}
-
-prepare() {
-  cd pipewire
-  # remove export of LD_LIBRARY_PATH for pw-jack as it would add /usr/lib
-  sed -e '/LD_LIBRARY_PATH/d' -i pipewire-jack/src/pw-jack.in
-}
-
-build() {
-  local meson_options=(
-    -D docs=enabled
-    -D jack=disabled
-    -D jack-devel=true
-    -D libjack-path=/usr/lib
-    -D libcamera=disabled
-    -D udevrulesdir=/usr/lib/udev/rules.d
-    -D roc=disabled
-    -D session-managers=[]
-  )
-
-  arch-meson pipewire build "${meson_options[@]}"
-  meson compile -C build
-}
-
-check() {
-  meson test -C build --print-errorlogs
-}
-
-_pick() {
-  local p="$1" f d; shift
-  for f; do
-    d="$srcdir/$p/${f#$pkgdir/}"
-    mkdir -p "$(dirname "$d")"
-    mv "$f" "$d"
-    rmdir -p --ignore-fail-on-non-empty "$(dirname "$f")"
-  done
-}
-
-_ver=${pkgver:0:3}
-
-package_pipewire() {
-  license+=(LGPL)  # libspa-alsa
-  depends=(alsa-card-profiles libdbus-1.so libncursesw.so libsndfile.so
-           libudev.so libusb-1.0.so libasound.so libsystemd.so libbluetooth.so
-           libsbc.so libldacBT_enc.so libfreeaptx.so libfdk-aac.so liblilv-0.so
-           libwebrtc_audio_processing.so)
-  optdepends=('pipewire-docs: Documentation'
-              'pipewire-session-manager: Session manager'
-              'pipewire-alsa: ALSA configuration'
-              'pipewire-jack: JACK support'
-              'pipewire-pulse: PulseAudio replacement'
-              'gst-plugin-pipewire: GStreamer plugin'
-              'pipewire-zeroconf: Zeroconf support'
-              'pipewire-v4l2: V4L2 interceptor'
-              'pipewire-x11-bell: X11 bell'
-              'realtime-privileges: realtime privileges with rt module'
-              'rtkit: realtime privileges with rtkit module')
-  provides=(libpipewire-$_ver.so)
-  install=pipewire.install
-
-  meson install -C build --destdir "$pkgdir"
-
-  ( cd "$pkgdir"
-
-    _pick acp usr/lib/udev
-    _pick acp usr/share/alsa-card-profile
-
-    _pick docs usr/share/doc
-
-    _pick jack usr/bin/pw-jack
-    _pick jack usr/include/jack
-    _pick jack usr/lib/libjack*
-    _pick jack usr/lib/pkgconfig/jack.pc
-    _pick jack usr/share/man/man1/pw-jack.1
-    _pick jack usr/share/pipewire/jack.conf
-
-    _pick pulse usr/bin/pipewire-pulse
-    _pick pulse usr/lib/pipewire-$_ver/libpipewire-module-protocol-pulse.so
-    _pick pulse usr/lib/pipewire-$_ver/libpipewire-module-pulse-tunnel.so
-    _pick pulse usr/lib/systemd/user/pipewire-pulse.*
-
-    _pick gst usr/lib/gstreamer-1.0
-
-    _pick zeroconf usr/lib/pipewire-$_ver/libpipewire-module-{raop,zeroconf}-discover.so
-
-    _pick v4l2 usr/bin/pw-v4l2 usr/lib/pipewire-$_ver/v4l2
-    _pick x11-bell usr/lib/pipewire-$_ver/libpipewire-module-x11-bell.so
-  )
-
-  mkdir -p "$pkgdir/etc/alsa/conf.d"
-  ln -st "$pkgdir/etc/alsa/conf.d" \
-    /usr/share/alsa/alsa.conf.d/50-pipewire.conf
-
-  install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 pipewire/COPYING
-}
-
-package_alsa-card-profiles() {
-  pkgdesc+=" - ALSA card profiles"
-  license=(LGPL)
-
-  mv acp/* "$pkgdir"
-}
-
-package_pipewire-docs() {
-  pkgdesc+=" - documentation"
-
-  mv docs/* "$pkgdir"
-
-  install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 pipewire/COPYING
-}
-
-package_pipewire-alsa() {
-  pkgdesc+=" - ALSA configuration"
-  depends=(pipewire-session-manager)
-  provides=(pulseaudio-alsa)
-
-  mkdir -p "$pkgdir/etc/alsa/conf.d"
-  ln -st "$pkgdir/etc/alsa/conf.d" \
-    /usr/share/alsa/alsa.conf.d/99-pipewire-default.conf
-
-  install -Dm644 /dev/null \
-    "$pkgdir/usr/share/pipewire/media-session.d/with-alsa"
-
-  install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 pipewire/COPYING
-}
-
-package_pipewire-jack() {
-  pkgdesc+=" - JACK support"
-  license+=(GPL2)  # libjackserver
-  depends=(sh pipewire-session-manager libpipewire-$_ver.so)
-  optdepends=('jack-example-tools: for official JACK example-clients and tools')
-  conflicts=(jack jack2)
-  provides=(jack libjack.so libjackserver.so libjacknet.so)
-
-  mv jack/* "$pkgdir"
-
-  install -Dm644 /dev/null \
-    "$pkgdir/usr/share/pipewire/media-session.d/with-jack"
-
-  install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 pipewire/COPYING
-}
-
-package_pipewire-pulse() {
-  pkgdesc+=" - PulseAudio replacement"
-  depends=(pipewire-session-manager libpipewire-$_ver.so libpulse.so
-           libavahi-{client,common}.so)
-  provides=(pulseaudio pulseaudio-bluetooth)
-  conflicts=(pulseaudio pulseaudio-bluetooth)
-  install=pipewire-pulse.install
-
-  mv pulse/* "$pkgdir"
-
-  install -Dm644 /dev/null \
-    "$pkgdir/usr/share/pipewire/media-session.d/with-pulseaudio"
-
-  install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 pipewire/COPYING
-}
-
-package_gst-plugin-pipewire() {
-  pkgdesc="Multimedia graph framework - pipewire plugin"
-  depends=(pipewire-session-manager libpipewire-$_ver.so gst-plugins-base-libs)
-
-  mv gst/* "$pkgdir"
-
-  install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 pipewire/COPYING
-}
-
-package_pipewire-zeroconf() {
-  pkgdesc+=" - Zeroconf support"
-  depends=(pipewire libpipewire-$_ver.so libavahi-{client,common}.so)
-
-  mv zeroconf/* "$pkgdir"
-
-  install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 pipewire/COPYING
-}
-
-package_pipewire-v4l2() {
-  pkgdesc+=" - V4L2 interceptor"
-  depends=(sh pipewire-session-manager libpipewire-$_ver.so)
-
-  mv v4l2/* "$pkgdir"
-
-  install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 pipewire/COPYING
-}
-
-
-package_pipewire-x11-bell() {
-  pkgdesc+=" - X11 bell"
-  depends=(libcanberra.so libpipewire-$_ver.so libx11)
-
-  mv x11-bell/* "$pkgdir"
-
-  install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 pipewire/COPYING
-}
-# vim:set sw=2 et:
diff --git a/extra/pipewire/pipewire-media-session.install b/extra/pipewire/pipewire-media-session.install
deleted file mode 100644
index af304d181..000000000
--- a/extra/pipewire/pipewire-media-session.install
+++ /dev/null
@@ -1,25 +0,0 @@
-post_install() {
-  # Enable service by default
-  # WantedBy=pipewire.service, which is itself socket-activated
-  systemctl --global enable pipewire-media-session.service
-}
-
-post_upgrade() {
-  if (( $(vercmp "$2" '0.3.23-1') < 0)); then
-    systemctl --global enable pipewire-media-session.service
-  fi
-
-  if (( $(vercmp "$2" '1:0.3.38-1') < 0)); then
-    printf "\tReenable any per-user enabled pipewire-media-session.service\n \
-      \tmanually to establish a new service alias for\n \
-      \tpipewire-session-manager.service added with 0.3.38.\n"
-    # reenable already enabled global pipewire-media-session.service, as an alias is introduced with 0.3.38
-    if systemctl --global is-enabled -q pipewire-media-session.service; then
-      systemctl --global reenable pipewire-media-session.service
-    fi
-  fi
-}
-
-pre_remove() {
-  systemctl --global disable pipewire-media-session.service
-}
diff --git a/extra/pipewire/pipewire-pulse.install b/extra/pipewire/pipewire-pulse.install
deleted file mode 100644
index 051abb3a0..000000000
--- a/extra/pipewire/pipewire-pulse.install
+++ /dev/null
@@ -1,14 +0,0 @@
-post_install() {
-  # Enable socket by default
-  systemctl --global enable pipewire-pulse.socket
-}
-
-post_upgrade() {
-  if (( $(vercmp $2 0.3.16-1) < 0)); then
-    systemctl --global enable pipewire-pulse.socket
-  fi
-}
-
-pre_remove() {
-  systemctl --global disable pipewire-pulse.socket
-}
diff --git a/extra/pipewire/pipewire.install b/extra/pipewire/pipewire.install
deleted file mode 100644
index 416e5ed97..000000000
--- a/extra/pipewire/pipewire.install
+++ /dev/null
@@ -1,14 +0,0 @@
-post_install() {
-  # Enable socket by default
-  systemctl --global enable pipewire.socket
-}
-
-post_upgrade() {
-  if (( $(vercmp $2 0.1.6-2) < 0)); then
-    systemctl --global enable pipewire.socket
-  fi
-}
-
-pre_remove() {
-  systemctl --global disable pipewire.socket
-}