added community/lxcfs

community/lxcfs/PKGBUILD

@@ -0,0 +1,41 @@
+# Maintainer: Sergej Pupykin <arch+pub@sergej.pp.ru>
+# Maintainer: Christian Brauner <christianvanbrauner@gmail.com>
+# Maintainer: Morten Linderud <foxboron@archlinux.org>
+
+# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
+#  - add -D_FILE_OFFSET_BITS=64 to CPPFLAGS
+
+pkgname=lxcfs
+pkgver=4.0.11
+pkgrel=1
+pkgdesc="FUSE filesystem for LXC"
+arch=(x86_64)
+url="https://linuxcontainers.org/"
+license=('GPL')
+depends=('lxc' 'libnih' 'fuse3' 'dbus-glib')
+makedepends=('help2man')
+options=('emptydirs')
+source=("https://linuxcontainers.org/downloads/lxcfs/lxcfs-$pkgver.tar.gz"{,.asc}
+	"lxcfs.service")
+validpgpkeys=('602F567663E593BCBD14F338C638974D64792D67')
+sha256sums=('6e511222a1ef8e11208fb895177d0832b21a6198545e85a19371ba721bb68055'
+            'SKIP'
+            '3549e83ebbd6ec5934be0c3137b0dbb1101cec098bc49d135fea29f733b9e2a1')
+
+build() {
+    cd "$srcdir/$pkgname-$pkgver"
+    CPPFLAGS+=" -D_FILE_OFFSET_BITS=64"
+    ./configure \
+        --prefix=/usr \
+        --sbindir=/usr/bin \
+        --with-pamdir=/usr/lib/security \
+        --localstatedir=/var
+    make
+}
+
+package() {
+    cd "$srcdir/$pkgname-$pkgver"
+    make DESTDIR="$pkgdir/" install
+    install -dm0755 "$pkgdir"/var/lib/lxcfs
+    install -Dm0644 "$srcdir"/lxcfs.service "$pkgdir"/usr/lib/systemd/system/lxcfs.service
+}

community/lxcfs/lxcfs.service

@@ -0,0 +1,13 @@
+[Unit]
+Description=FUSE filesystem for LXC
+ConditionVirtualization=!container
+Before=lxc.service
+
+[Service]
+ExecStart=/usr/bin/lxcfs /var/lib/lxcfs
+KillMode=process
+Restart=on-failure
+ExecStopPost=-/bin/fusermount -u /var/lib/lxcfs
+
+[Install]
+WantedBy=multi-user.target