added extra/gjs

extra/gjs/PKGBUILD

@@ -0,0 +1,46 @@
+# $Id$
+# Contributor: Ionut Biru <ibiru@archlinux.org>
+
+# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
+#  - configure with --enable-compile-warnings=no
+
+pkgname=gjs
+pkgver=1.48.3
+pkgrel=1
+pkgdesc="Javascript Bindings for GNOME"
+url="https://wiki.gnome.org/Projects/Gjs"
+arch=(i686 x86_64)
+license=(GPL)
+depends=(cairo gobject-introspection-runtime js38 gtk3)
+makedepends=(gobject-introspection git gnome-common)
+_commit=9e64b210af822883de887916d560a2d7c95a0fe3  # tags/1.48.3^0
+source=("git+https://git.gnome.org/browse/gjs#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+  cd $pkgname
+  ./configure --prefix=/usr --disable-static --libexecdir=/usr/lib --enable-compile-warnings=no
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+  make
+}
+
+check() {
+  cd $pkgname
+  # Needs a display
+  make -k check || :
+}
+
+package() {
+  cd $pkgname
+  make DESTDIR="$pkgdir" install
+}