mirror of
https://github.com/archlinuxarm/PKGBUILDs.git
synced 2024-11-18 22:54:00 +00:00
added extra/calligra
This commit is contained in:
Kevin Mihelich
parent
a1db479f3a
commit
0f0878ffa4
2 changed files with 287 additions and 0 deletions
236
extra/calligra/PKGBUILD
Normal file
236
extra/calligra/PKGBUILD
Normal file
|
|
@ -0,0 +1,236 @@
|
|||
# $Id$
|
||||
# Maintainer: Felix Yan <felixonmars@archlinux.org>
|
||||
# Maintainer: Antonio Rojas <arojas@archlinux.org>
|
||||
# Contributor: Andrea Scarpino <andrea@archlinux.org>
|
||||
# Contributor: Ronald van Haren <ronald.archlinux.org>
|
||||
|
||||
# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
|
||||
# - upstream patch for signed char on ARM
|
||||
|
||||
pkgbase=calligra
|
||||
pkgname=('calligra-braindump'
|
||||
'calligra-devtools'
|
||||
'calligra-extras'
|
||||
'calligra-filters'
|
||||
'calligra-flow'
|
||||
'calligra-gemini'
|
||||
'calligra-handbook'
|
||||
'calligra-karbon'
|
||||
'calligra-kexi'
|
||||
'calligra-libs'
|
||||
'calligra-plan'
|
||||
'calligra-plugins'
|
||||
'calligra-sheets'
|
||||
'calligra-stage'
|
||||
'calligra-words')
|
||||
pkgver=2.9.11
|
||||
pkgrel=4
|
||||
arch=('i686' 'x86_64')
|
||||
url='http://www.calligra-suite.org/'
|
||||
license=('FDL1.2' 'GPL2' 'LGPL')
|
||||
makedepends=('cmake' 'automoc4' 'boost' 'kdepimlibs4' 'eigen' 'libmarble4'
|
||||
'lcms2' 'libmariadbclient' 'freetds' 'xbase' 'libwpg'
|
||||
'libwps' 'gsl' 'glew' 'fftw' 'poppler-qt4' 'libodfgen'
|
||||
'openjpeg' 'kdegraphics-okular' 'pstoedit' 'libvisio'
|
||||
'libetonyek' 'libpqxx' 'libspnav' 'postgresql') # 'libqgit2'
|
||||
groups=('calligra')
|
||||
source=("http://download.kde.org/stable/${pkgbase}-${pkgver}/${pkgbase}-${pkgver}.tar.xz" 'libwps-0.4.patch'
|
||||
'https://github.com/KDE/calligra/commit/956bb80db4f300e4f8edeaf19d24fd61eb1932b2.patch')
|
||||
md5sums=('a1a4935debae64724cd4c0d17d61ae4e'
|
||||
'6ea15f8b3938838d89ea0aa08921afd1'
|
||||
'47305e6e25a076d5761e7b22a65b777e')
|
||||
|
||||
prepare() {
|
||||
mkdir -p build
|
||||
|
||||
# Fix build against libwps 0.4
|
||||
cd $pkgbase-$pkgver
|
||||
patch -p1 -i "$srcdir"/libwps-0.4.patch
|
||||
|
||||
# Fix build against libmarble4
|
||||
sed -e 's|PATH_SUFFIXES marble|PATH_SUFFIXES marble4|g' -i CMakeLists.txt
|
||||
sed -e 's|#include <marble/|#include <marble4/|g' -e 's|#include "marble/|#include "marble4/|g' \
|
||||
-i plugins/reporting/maps/{*.cpp,*.h,marble/*.h} -i kexi/plugins/forms/widgets/mapbrowser/{*.cpp,*.h}
|
||||
|
||||
# Fix build on ARM
|
||||
patch -p1 -i ../956bb80db4f300e4f8edeaf19d24fd61eb1932b2.patch
|
||||
}
|
||||
|
||||
build() {
|
||||
cd build
|
||||
cmake ../${pkgbase}-${pkgver} \
|
||||
-DCMAKE_BUILD_TYPE=Release \
|
||||
-DCMAKE_INSTALL_PREFIX=/usr \
|
||||
-DCMAKE_INSTALL_LIBDIR=lib \
|
||||
-DBUILD_active=OFF \
|
||||
-DWITH_Soprano=OFF \
|
||||
-DBUILD_krita=OFF \
|
||||
-DMARBLE_INCLUDE_DIR=/usr/include/marble4 \
|
||||
-DMARBLE_GLOBAL_HEADER=/usr/include/marble4/MarbleGlobal.h \
|
||||
-DMARBLE_LIBRARIES=/usr/lib/libmarblewidget.so
|
||||
make
|
||||
}
|
||||
|
||||
package_calligra-filters() {
|
||||
pkgdesc="Filters for the Calligra office suite"
|
||||
depends=('libodfgen')
|
||||
optdepends=('libwpg: Corel WordPerfect Graphics image importer'
|
||||
'libwps: Microsoft Works file word processor format import'
|
||||
'libvisio: Microsoft Visio import filter'
|
||||
'libetonyek: Apple Keynote import filter')
|
||||
|
||||
cd build/filters
|
||||
make DESTDIR="${pkgdir}" install
|
||||
}
|
||||
|
||||
package_calligra-libs() {
|
||||
pkgdesc="Libraries for the Calligra office suite"
|
||||
depends=('kdepimlibs4' 'libkactivities4')
|
||||
conflicts=('calligra-interfaces' 'calligra-pics' 'calligra-servicetypes')
|
||||
replaces=('calligra-interfaces' 'calligra-pics' 'calligra-servicetypes')
|
||||
|
||||
for d in interfaces libs pics servicetypes; do
|
||||
cd "${srcdir}"/build/${d}
|
||||
make DESTDIR="${pkgdir}" install
|
||||
done
|
||||
}
|
||||
|
||||
package_calligra-plugins() {
|
||||
pkgdesc="Plugins for the Calligra office suite"
|
||||
depends=('calligra-libs' 'calligra-filters' 'libspnav')
|
||||
optdepends=('libmarble4: map shape for Calligra')
|
||||
|
||||
cd build/plugins
|
||||
make DESTDIR="${pkgdir}" install
|
||||
|
||||
cd ../3rdparty/kdchart
|
||||
make DESTDIR="${pkgdir}" install
|
||||
}
|
||||
|
||||
package_calligra-karbon() {
|
||||
pkgdesc="Create scalable vector drawings"
|
||||
depends=('calligra-libs' 'kdebase-runtime' 'pstoedit')
|
||||
optdepends=('calligra-filters: import/export filters'
|
||||
'calligra-extras: extra calligra tools')
|
||||
|
||||
cd build/karbon
|
||||
make DESTDIR="${pkgdir}" install
|
||||
}
|
||||
|
||||
package_calligra-kexi() {
|
||||
pkgdesc="Develop desktop database applications"
|
||||
depends=('calligra-libs' 'glew' 'fftw')
|
||||
optdepends=('libmariadbclient: MariaDB driver'
|
||||
'libpqxx: PostgreSQL driver'
|
||||
'freetds: Sybase & MS SQL driver'
|
||||
'xbase: XBase driver'
|
||||
'calligra-sheets: Spreadsheet-to-Kexi-table import plugin'
|
||||
'libmarble4: map form widget'
|
||||
'calligra-plugins: extra calligra plugins')
|
||||
|
||||
cd build/kexi
|
||||
make DESTDIR="${pkgdir}" install
|
||||
cd ../doc/kexi
|
||||
make DESTDIR="${pkgdir}" install
|
||||
}
|
||||
|
||||
package_calligra-plan() {
|
||||
pkgdesc="Calligra Project Management Component"
|
||||
depends=('calligra-words')
|
||||
|
||||
cd build/plan
|
||||
make DESTDIR="${pkgdir}" install
|
||||
|
||||
cd ../3rdparty/kdgantt
|
||||
make DESTDIR="${pkgdir}" install
|
||||
}
|
||||
|
||||
package_calligra-stage() {
|
||||
pkgdesc="Write presentation documents"
|
||||
depends=('calligra-plugins' 'kdebase-runtime')
|
||||
|
||||
cd build/stage
|
||||
make DESTDIR="${pkgdir}" install
|
||||
cd ../doc/stage
|
||||
make DESTDIR="${pkgdir}" install
|
||||
}
|
||||
|
||||
package_calligra-sheets() {
|
||||
pkgdesc="Write spreadsheet documents"
|
||||
depends=('calligra-libs' 'gsl' 'kdebase-runtime')
|
||||
optdepends=('calligra-filters: import/export filters'
|
||||
'calligra-plugins: extra calligra plugins'
|
||||
'calligra-extras: extra calligra tools')
|
||||
|
||||
cd build/sheets
|
||||
make DESTDIR="${pkgdir}" install
|
||||
cd ../doc/sheets
|
||||
make DESTDIR="${pkgdir}" install
|
||||
}
|
||||
|
||||
package_calligra-words() {
|
||||
pkgdesc="Word Processor"
|
||||
depends=('kdebase-runtime' 'calligra-plugins')
|
||||
optdepends=('calligra-extras: extra calligra tools')
|
||||
|
||||
cd build/words
|
||||
make DESTDIR="${pkgdir}" install
|
||||
}
|
||||
|
||||
package_calligra-handbook() {
|
||||
pkgdesc="Documentation for Calligra"
|
||||
options=('docs')
|
||||
|
||||
cd build/doc/calligra
|
||||
make DESTDIR="${pkgdir}" install
|
||||
}
|
||||
|
||||
package_calligra-braindump() {
|
||||
pkgdesc="Notes and idea gathering"
|
||||
depends=('calligra-libs' 'kdebase-runtime')
|
||||
|
||||
cd build/braindump
|
||||
make DESTDIR="${pkgdir}" install
|
||||
}
|
||||
|
||||
package_calligra-flow() {
|
||||
pkgdesc="Flowchart & Diagram Editing"
|
||||
depends=('calligra-words')
|
||||
optdepends=('calligra-karbon: to export the charts in various formats')
|
||||
|
||||
cd build/flow
|
||||
make DESTDIR="${pkgdir}" install
|
||||
}
|
||||
|
||||
package_calligra-extras() {
|
||||
pkgdesc="Calligra suite extras"
|
||||
depends=('calligra-libs')
|
||||
optdepends=('kdegraphics-okular')
|
||||
conflicts=('calligra-tools')
|
||||
replaces=('calligra-tools')
|
||||
|
||||
cd build/extras
|
||||
make DESTDIR="${pkgdir}" install
|
||||
|
||||
cd ../data
|
||||
make DESTDIR="${pkgdir}" install
|
||||
}
|
||||
|
||||
package_calligra-devtools() {
|
||||
pkgdesc="Calligra developer tools"
|
||||
depends=('calligra-libs')
|
||||
|
||||
cd build/devtools
|
||||
make DESTDIR="${pkgdir}" install
|
||||
}
|
||||
|
||||
package_calligra-gemini() {
|
||||
pkgdesc="QML interface for Calligra Words and Stage"
|
||||
depends=('calligra-words' 'calligra-stage')
|
||||
# optdepends=('libqgit2: GIT plugin')
|
||||
|
||||
cd build/qtquick
|
||||
make DESTDIR="${pkgdir}" install
|
||||
cd "${srcdir}"/build/gemini
|
||||
make DESTDIR="${pkgdir}" install
|
||||
}
|
||||
51
extra/calligra/libwps-0.4.patch
Normal file
51
extra/calligra/libwps-0.4.patch
Normal file
|
|
@ -0,0 +1,51 @@
|
|||
From e81fe84405bc635dfa93e54fb8a3c8e6065dbf10 Mon Sep 17 00:00:00 2001
|
||||
From: David Tardon <dtardon@redhat.com>
|
||||
Date: Sat, 6 Jun 2015 18:27:24 +0200
|
||||
Subject: [PATCH] adapt to libwps 0.4
|
||||
|
||||
---
|
||||
cmake/modules/FindLibWps.cmake | 6 +++---
|
||||
filters/words/works/import/WPSImport.cpp | 4 +++-
|
||||
2 files changed, 6 insertions(+), 4 deletions(-)
|
||||
|
||||
diff --git a/cmake/modules/FindLibWps.cmake b/cmake/modules/FindLibWps.cmake
|
||||
index f8c8225..58ef2b5 100644
|
||||
--- a/cmake/modules/FindLibWps.cmake
|
||||
+++ b/cmake/modules/FindLibWps.cmake
|
||||
@@ -10,16 +10,16 @@
|
||||
|
||||
include(LibFindMacros)
|
||||
libfind_package(LIBWPS LibWpd)
|
||||
-libfind_pkg_check_modules(LIBWPS_PKGCONF libwps-0.3)
|
||||
+libfind_pkg_check_modules(LIBWPS_PKGCONF libwps-0.4)
|
||||
|
||||
find_path(LIBWPS_INCLUDE_DIR
|
||||
NAMES libwps/libwps.h
|
||||
HINTS ${LIBWPS_PKGCONF_INCLUDE_DIRS} ${LIBWPS_PKGCONF_INCLUDEDIR}
|
||||
- PATH_SUFFIXES libwps-0.3
|
||||
+ PATH_SUFFIXES libwps-0.4
|
||||
)
|
||||
|
||||
find_library(LIBWPS_LIBRARY
|
||||
- NAMES wps wps-0.3
|
||||
+ NAMES wps wps-0.4
|
||||
HINTS ${LIBWPS_PKGCONF_LIBRARY_DIRS} ${LIBWPS_PKGCONF_LIBDIR}
|
||||
)
|
||||
|
||||
diff --git a/filters/words/works/import/WPSImport.cpp b/filters/words/works/import/WPSImport.cpp
|
||||
index eea2cc9..94b859d 100644
|
||||
--- a/filters/words/works/import/WPSImport.cpp
|
||||
+++ b/filters/words/works/import/WPSImport.cpp
|
||||
@@ -91,7 +91,9 @@ public:
|
||||
bool isSupportedFormat(librevenge::RVNGInputStream &input)
|
||||
{
|
||||
WPSKind kind = WPS_TEXT;
|
||||
- WPSConfidence confidence = WPSDocument::isFileFormatSupported(&input, kind);
|
||||
+ WPSCreator creator = WPS_MSWORKS;
|
||||
+ bool needsEncoding = false;
|
||||
+ WPSConfidence confidence = WPSDocument::isFileFormatSupported(&input, kind, creator, needsEncoding);
|
||||
if (confidence == WPS_CONFIDENCE_NONE || kind != WPS_TEXT)
|
||||
return false;
|
||||
return true;
|
||||
--
|
||||
2.4.2
|
||||
Loading…
Reference in a new issue