added community/xxhash

community/xxhash/PKGBUILD

@@ -0,0 +1,50 @@
+# Maintainer: Maxime Gauduin <alucryd@archlinux.org>
+# Contributor: Fabien Dubosson <fabien.dubosson@gmail.com>
+# Contributor: Konstantin Gizdov <arch@kge.com>
+
+# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
+#  - set DISPATCH=0, x86 only
+
+pkgname=xxhash
+pkgver=0.8.1
+pkgrel=4
+pkgdesc='Extremely fast non-cryptographic hash algorithm'
+arch=(x86_64)
+url=https://cyan4973.github.io/xxHash/
+license=(
+  GPL2
+  BSD
+)
+depends=(glibc)
+makedepends=(git)
+provides=(libxxhash.so)
+_tag=35b0373c697b5f160d3db26b1cbb45a0d5ba788c
+source=(
+  git+https://github.com/Cyan4973/xxHash.git#tag=${_tag}
+  xxhash-man-symlinks.patch
+)
+b2sums=(
+  SKIP
+  83236ec7363f98842a5c8deb52e0a200321a722748a69b472b42b65eb85fa06ac5490926ea7612c0c455bf4998e109567706cf0f03e2c52c1e497abf258e5219
+)
+
+prepare() {
+  cd xxHash
+  patch -Np1 -i ../xxhash-man-symlinks.patch
+}
+
+pkgver() {
+  cd xxHash
+  git describe --tags | sed 's/^v//'
+}
+
+build() {
+  make PREFIX=/usr DISPATCH=0 -C xxHash
+}
+
+package() {
+  make PREFIX=/usr DISPATCH=0 DESTDIR="${pkgdir}" -C xxHash install
+  install -Dm 644 xxHash/LICENSE -t "${pkgdir}"/usr/share/licenses/xxhash
+}
+
+# vim: ts=2 sw=2 et:

community/xxhash/xxhash-man-symlinks.patch

@@ -0,0 +1,16 @@
+diff '--color=auto' -rupN xxHash.orig/Makefile xxHash/Makefile
+--- xxHash.orig/Makefile	2021-12-06 11:36:16.742156574 +0100
++++ xxHash/Makefile	2021-12-06 11:37:31.712450289 +0100
+@@ -518,9 +518,9 @@ endif
+ 	$(Q)ln -sf xxhsum $(DESTDIR)$(BINDIR)/xxh128sum
+ 	@echo Installing man pages
+ 	$(Q)$(INSTALL_DATA) $(MAN) $(DESTDIR)$(MANDIR)/xxhsum.1
+-	$(Q)ln -sf $(MAN) $(DESTDIR)$(MANDIR)/xxh32sum.1
+-	$(Q)ln -sf $(MAN) $(DESTDIR)$(MANDIR)/xxh64sum.1
+-	$(Q)ln -sf $(MAN) $(DESTDIR)$(MANDIR)/xxh128sum.1
++	$(Q)ln -sf xxhsum.1.gz $(DESTDIR)$(MANDIR)/xxh32sum.1.gz
++	$(Q)ln -sf xxhsum.1.gz $(DESTDIR)$(MANDIR)/xxh64sum.1.gz
++	$(Q)ln -sf xxhsum.1.gz $(DESTDIR)$(MANDIR)/xxh128sum.1.gz
+ 	@echo xxhash installation completed
+ 
+ .PHONY: uninstall