added community/python-cairosvg

community/python-cairosvg/PKGBUILD

@@ -0,0 +1,44 @@
+# Maintainer: Felix Yan <felixonmars@archlinux.org>
+# Maintainer: Filipe Laíns (FFY00) <lains@archlinux.org>
+
+# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
+#  - depend on python-cairo instead of python-cairocffi (haskell deps)
+
+pkgname=python-cairosvg
+_pkgname=CairoSVG
+pkgver=2.4.0
+pkgrel=1
+pkgdesc='SVG converter based on Cairo. It can export SVG files to PDF, PostScript and PNG files'
+arch=('any')
+url='https://cairosvg.org'
+license=('LGPL3')
+depends=('python' 'python-setuptools' 'python-cairo' 'python-pillow' 'python-cssselect2' 'python-defusedxml' 'python-tinycss2')
+checkdepends=('python-pytest-runner' 'python-pytest-cov' 'python-pytest-flake8' 'python-pytest-isort')
+replaces=('cairosvg')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/Kozea/CairoSVG/archive/$pkgver.tar.gz")
+sha512sums=('53a39e7fef356a5757e9c31b509e99152b2506d337d87fb5035589da7a7a79515474090f458244ee9425afced2b5218bd48d0c77b472aeca1c61efd633409428')
+
+prepare() {
+  cd $_pkgname-$pkgver
+
+  cp -r cairosvg test_non_regression/cairosvg_reference/
+}
+
+build() {
+  cd $_pkgname-$pkgver
+
+  python setup.py build
+}
+
+check() {
+  cd $_pkgname-$pkgver
+
+  python setup.py pytest
+}
+
+package() {
+  cd $_pkgname-$pkgver
+
+  python setup.py install --root="$pkgdir" --optimize=1 --skip-build
+}
+