added community/python-aws-xray-sdk

community/python-aws-xray-sdk/PKGBUILD

@@ -0,0 +1,50 @@
+# Maintainer: Chih-Hsuan Yen <yan12125@archlinux.org>
+# Contributor: Guillaume Horel <guillaume.horel@gmail.com>
+
+# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
+#  - remove makedepend on python-pypandoc
+
+pkgname=python-aws-xray-sdk
+_pkgname=aws-xray-sdk-python
+pkgver=2.4.2
+pkgrel=2
+pkgdesc='AWS X-Ray SDK for Python'
+arch=(any)
+url='https://github.com/aws/aws-xray-sdk-python'
+license=(Apache)
+makedepends=(python-setuptools)
+depends=(python python-botocore python-future python-jsonpickle python-wrapt)
+checkdepends=(python-flask-sqlalchemy python-pynamodb python-pytest python-aiohttp
+              python-pytest-aiohttp python-testing.postgresql python-psycopg2
+              python-pg8000 python-requests python-aiobotocore)
+# Not using PyPI source tarball as it does not include tests
+source=("https://github.com/aws/aws-xray-sdk-python/archive/$pkgver/$pkgname-$pkgver.tar.gz"
+        "aws-xray-sdk-psycopg2.8.patch"::"https://github.com/aws/aws-xray-sdk-python/commit/4b4422a3ad9bb9a28399b34851dd574f6155bb66.patch")
+sha256sums=('e480a6dc21d314faf6a9af4cf871fd7b782fae1e704e0fe5977161707f101374'
+            'b0740901e4c3bd0a678b217b1121c5f827e8535722a560d9f84fb9a8b90f8f74')
+
+prepare() {
+  cd $_pkgname-$pkgver
+  patch -Np1 -i ../aws-xray-sdk-psycopg2.8.patch
+}
+
+build() {
+  cd $_pkgname-$pkgver
+  python setup.py build
+}
+
+check() {
+  cd $_pkgname-$pkgver
+
+  export AWS_SECRET_ACCESS_KEY=fake_key
+  export AWS_ACCESS_KEY_ID=fake_id
+
+  # the test suite is not compatible with Django 2.x yet
+  # https://github.com/aws/aws-xray-sdk-python/issues/85
+  pytest -v --ignore tests/ext/django
+}
+
+package() {
+  cd $_pkgname-$pkgver
+  python setup.py install --root="$pkgdir" --optimize=1 --skip-build
+}