From 3c14719486835c294543002e28ac9d00b39ccfa1 Mon Sep 17 00:00:00 2001
From: Kevin Mihelich <kevin@archlinuxarm.org>
Date: Sat, 23 Jul 2022 21:12:27 +0000
Subject: [PATCH] added community/xine-lib

---
 community/xine-lib/PKGBUILD | 58 +++++++++++++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)
 create mode 100644 community/xine-lib/PKGBUILD

diff --git a/community/xine-lib/PKGBUILD b/community/xine-lib/PKGBUILD
new file mode 100644
index 000000000..9f12c666e
--- /dev/null
+++ b/community/xine-lib/PKGBUILD
@@ -0,0 +1,58 @@
+# Maintainer : Daniel Bermond <dbermond@archlinux.org>
+# Contributor: Eric BĂ©langer <eric@archlinux.org>
+
+# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
+#  - configure with --without-dav1d, FTBFS
+
+pkgname=xine-lib
+pkgver=1.2.12
+pkgrel=2
+pkgdesc='Multimedia playback engine'
+arch=('x86_64')
+url='https://www.xine-project.org'
+license=('GPL' 'LGPL')
+depends=('ffmpeg' 'libjpeg-turbo' 'libnsl' 'libpng' 'libx11' 'libxcb'
+         'libxext' 'libxinerama' 'libxv' 'libxvmc' 'zlib')
+optdepends=('libdvdnav: for dvd plugin'
+            'libdvdread: for spu and dxr3 plugins'
+            'vcdimager: for vcd plugin'
+            'glu: for opengl and vaapi plugins'
+            'sdl: for sdl plugin'
+            'wayland: for egl_wl plugin'
+            'aalib: for aalib plugin'
+            'a52dec: for a52 plugin'
+            'faad2: for faad plugin'
+            'flac: for flac plugin'
+            'libdca: for dts (dca) plugin'
+            'libmad: for mad (mp3) plugin'
+            'libmpcdec: for mpc (musepack) plugin'
+            'wavpack: for wavpack plugin'
+            'gdk-pixbuf2: for gdk_pixbuf plugin'
+            'imagemagick: for imagemagick plugin'
+            'libcaca: for caca plugin'
+            'libmng: for mng plugin'
+            'libnfs: for nfs plugin'
+            'libssh2: for ssh plugin'
+            'smbclient: for samba plugin')
+makedepends=('mesa' 'libdvdnav' 'libdvdread' 'vcdimager' 'glu' 'sdl'
+             'wayland' 'aalib' 'a52dec' 'faad2' 'flac' 'libdca' 'libmad'
+             'libmpcdec' 'wavpack' 'gdk-pixbuf2' 'imagemagick' 'libcaca'
+             'libmng' 'libnfs' 'smbclient')
+source=("https://downloads.sourceforge.net/project/xine/xine-lib/${pkgver}/xine-lib-${pkgver}.tar.xz")
+sha256sums=('d606270468e1540c2a89c0d7f5fdf11e17ecc0c2698cc0bcb1065ff26abee098')
+
+build() {
+    cd "${pkgname}-${pkgver}"
+    ./configure \
+        --prefix='/usr' \
+        --enable-antialiasing \
+        --with-external-dvdnav \
+        --with-wavpack \
+        --without-dav1d
+    sed -i 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+    make
+}
+
+package() {
+    make -C "${pkgname}-${pkgver}" DESTDIR="$pkgdir" install
+}