added extra/qt5-webkit-ng

extra/qt5-webkit-ng/PKGBUILD

@@ -0,0 +1,50 @@
+# $Id: PKGBUILD 240297 2015-06-03 10:22:03Z fyan $
+# Maintainer: Felix Yan <felixonmars@archlinux.org>
+# Contributor: Andrea Scarpino <andrea@archlinux.org>
+
+# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
+#  - disable jit on v5/v6
+
+pkgname=qt5-webkit-ng
+_qtver=tp4
+pkgver=${_qtver/-/}
+pkgrel=1
+arch=(i686 x86_64)
+url='https://github.com/annulen/webkit/wiki'
+license=(GPL3 LGPL3 FDL custom)
+pkgdesc='Classes for a WebKit2 based implementation and a new QML API (maintained fork)'
+depends=(qt5-location qt5-sensors qt5-webchannel libwebp libxslt libxcomposite gst-plugins-base hyphen)
+makedepends=(cmake ruby gperf python2 qt5-doc qt5-tools)
+optdepends=('gst-plugins-good: Webm codec support')
+conflicts=(qt5-webkit)
+provides=(qt5-webkit)
+source=("https://github.com/annulen/webkit/archive/qtwebkit-$pkgver.tar.gz")
+md5sums=('d923032e9edc86e2adef389d86f52e7f')
+
+prepare() {
+  mkdir -p build
+}
+
+build() {
+  cd build  
+
+  [[ $CARCH == "arm" || $CARCH == "armv6h" ]] && CONFIG="-DENABLE_JIT=OFF"
+
+  cmake ../webkit-qtwebkit-$pkgver \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DPORT=Qt $CONFIG
+  make
+}
+
+package() {
+  cd build
+  make DESTDIR="$pkgdir" install
+
+  # Drop QMAKE_PRL_BUILD_DIR because reference the build dir
+  find "$pkgdir/usr/lib" -type f -name '*.prl' \
+    -exec sed -i -e '/^QMAKE_PRL_BUILD_DIR/d' {} \;
+
+  install -d "$pkgdir"/usr/share/licenses
+  ln -s /usr/share/licenses/qt5-base "$pkgdir"/usr/share/licenses/${pkgname}
+}