removed extra/dav1d

extra/dav1d/PKGBUILD

@@ -1,62 +0,0 @@
-# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
-
-# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
-#  - disable assembly on v5/v6
-
-pkgbase=dav1d
-pkgname=(dav1d dav1d-doc)
-pkgver=0.9.2
-pkgrel=1
-pkgdesc='AV1 cross-platform decoder focused on speed and correctness'
-url='https://code.videolan.org/videolan/dav1d/'
-arch=('x86_64')
-license=('BSD')
-makedepends=('meson' 'ninja' 'nasm' 'doxygen' 'graphviz' 'xxhash')
-source=(https://downloads.videolan.org/pub/videolan/${pkgname}/${pkgver}/${pkgname}-${pkgver}.tar.xz{,.asc}
-        https://code.videolan.org/videolan/dav1d-test-data/-/archive/${pkgver}/dav1d-test-data-${pkgver}.tar.gz)
-sha512sums=('87026f8b14e408ff50fc8f137ec2ede4b14c5f69687e615d2359d0f718ae5cb5176522490786d9ae1f7838182f82615c2674f7c2961b6dcec83f1ee587c3af7c'
-            'SKIP'
-            '99c7546964b1c7187257b85057c41ad0698fd00920c7cd3b7e8cd8bc173965f03b3e64729ab11f72dd8125bd0fc7228752da64b69d8087cbd973b1a64f249188')
-b2sums=('7baa28821b06b05b95d3ea80b22dffe59d0793c9b4be4231ba0be99b548e1f5517a956dc865c2be1702576d078c2218e7e80342a26ab4003b4f06bcb0cdbb769'
-        'SKIP'
-        '750b1fb40ee8db873b9eb1a7f3b8923546d4782ca790bcbcc25c7bf13ccd3193dff3adfc75c32d877c722afb0392fad74632bddc46090d00e15d57b25c2f7716')
-validpgpkeys=('65F7C6B4206BD057A7EB73787180713BE58D1ADC') # VideoLAN Release Signing Key
-
-prepare() {
-  cd ${pkgbase}-${pkgver}
-  ln -s "${srcdir}/dav1d-test-data-${pkgver}" tests/dav1d-test-data
-}
-
-build() {
-  cd ${pkgbase}-${pkgver}
-  [[ $CARCH == "arm" || $CARCH == "armv6h" ]] && meson_options="-Dbuild_asm=false"
-  arch-meson -Dtestdata_tests=true $meson_options build
-  ninja -C build all doc/html
-}
-
-check() {
-  cd ${pkgbase}-${pkgver}/build
-  meson test
-}
-
-package_dav1d() {
-  depends=('glibc')
-  provides=('libdav1d.so')
-  optdepends=('dav1d-doc: HTML documentation')
-
-  cd ${pkgbase}-${pkgver}
-  DESTDIR="${pkgdir}" ninja -C build install
-  install -Dm 644 README.md CONTRIBUTING.md NEWS -t "${pkgdir}/usr/share/doc/${pkgname}"
-  install -Dm 644 COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}"
-}
-
-package_dav1d-doc() {
-  pkgdesc+=" (documentation)"
-
-  cd ${pkgbase}-${pkgver}
-  install -d "${pkgdir}/usr/share/doc/${pkgbase}"
-  cp -r build/doc/html -t "${pkgdir}/usr/share/doc/${pkgbase}"
-  install -Dm 644 COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}"
-}
-
-# vim: ts=2 sw=2 et: