diff --git a/extra/libqmi/PKGBUILD b/extra/libqmi/PKGBUILD
new file mode 100644
index 000000000..2eb4caf66
--- /dev/null
+++ b/extra/libqmi/PKGBUILD
@@ -0,0 +1,46 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
+
+# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
+#  - configure with --enable-qrtr
+
+pkgname=libqmi
+pkgver=1.26.8
+pkgrel=1.1
+pkgdesc="QMI modem protocol helper library"
+arch=(x86_64)
+url="https://www.freedesktop.org/wiki/Software/libqmi/"
+license=(GPL2)
+depends=(libmbim libgudev)
+makedepends=(gtk-doc python git help2man autoconf-archive gobject-introspection)
+provides=(libqmi-glib.so)
+_commit=45dad5abe0598af69b7fdb895b1705aa64a26ef9  # tags/1.26.8
+source=("git+https://gitlab.freedesktop.org/mobile-broadband/libqmi.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-rc/rc/;s/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+  cd $pkgname
+  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
+    --libexecdir=/usr/lib --disable-static --enable-gtk-doc \
+    --enable-compile-warnings=yes --enable-qrtr
+  make
+}
+
+check() {
+  cd $pkgname
+  make check
+}
+
+package() {
+  cd $pkgname
+  make DESTDIR="$pkgdir" install
+}