From 5797eea962c6a226c0f883ea0be09704f434c5a2 Mon Sep 17 00:00:00 2001
From: Kevin Mihelich <kevin@archlinuxarm.org>
Date: Sat, 25 Nov 2017 20:38:43 +0000
Subject: [PATCH] added alarm/xf86-video-freedreno

---
 alarm/xf86-video-freedreno/42-freedreno.conf |  4 ++
 alarm/xf86-video-freedreno/PKGBUILD          | 42 ++++++++++++++++++++
 2 files changed, 46 insertions(+)
 create mode 100644 alarm/xf86-video-freedreno/42-freedreno.conf
 create mode 100644 alarm/xf86-video-freedreno/PKGBUILD

diff --git a/alarm/xf86-video-freedreno/42-freedreno.conf b/alarm/xf86-video-freedreno/42-freedreno.conf
new file mode 100644
index 000000000..7261d804e
--- /dev/null
+++ b/alarm/xf86-video-freedreno/42-freedreno.conf
@@ -0,0 +1,4 @@
+Section "Device"
+        Identifier      "Video Device"
+        Driver          "freedreno"
+EndSection
diff --git a/alarm/xf86-video-freedreno/PKGBUILD b/alarm/xf86-video-freedreno/PKGBUILD
new file mode 100644
index 000000000..0abb8fa4d
--- /dev/null
+++ b/alarm/xf86-video-freedreno/PKGBUILD
@@ -0,0 +1,42 @@
+# Xorg video driver for Adreno mobile GPUs
+# Maintainer: Kevin Mihelich <kevin@archlinuxarm.org>
+
+buildarch=12
+
+pkgname=xf86-video-freedreno
+pkgver=1.4.0.r4.gccba8f8
+pkgrel=1
+pkgdesc='X.org graphics driver for Adreno mobile GPUs'
+arch=('armv7h')
+url="https://cgit.freedesktop.org/xorg/driver/xf86-video-freedreno/"
+license=('custom')
+makedepends=('xorg-server-devel' 'X-ABI-VIDEODRV_VERSION=23' 'git')
+conflicts=('xorg-server<1.19' 'X-ABI-VIDEODRV_VERSION<23' 'X-ABI-VIDEODRV_VERSION>=24')
+backup=('etc/X11/xorg.conf.d/42-freedreno.conf')
+source=('git+https://anongit.freedesktop.org/git/xorg/driver/xf86-video-freedreno.git'
+        '42-freedreno.conf')
+md5sums=('SKIP'
+         'b6703241877849a98da4e85f9dc77191')
+
+pkgver() {
+  cd $pkgname
+  git describe --long | sed "s/${pkgname}-//;s/\([^-]*-g\)/r\1/;s/-/./g"
+}
+
+build() {
+  cd $pkgname
+
+  export CFLAGS=${CFLAGS/-fno-plt}
+  export CXXFLAGS=${CXXFLAGS/-fno-plt}
+  export LDFLAGS=${LDFLAGS/,-z,now}
+
+  ./autogen.sh --prefix=/usr
+  make
+}
+
+package() {
+  cd $pkgname
+  make DESTDIR="$pkgdir" install
+  install -Dm644 ../42-freedreno.conf "$pkgdir/etc/X11/xorg.conf.d/42-freedreno.conf"
+  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
+}