added extra/krita

extra/krita/PKGBUILD

@@ -0,0 +1,41 @@
+# $Id: PKGBUILD 262594 2016-03-26 20:49:29Z arojas $
+# Maintainer: Antonio Rojas <arojas@archlinux,org>
+
+# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
+#  - remove makedepend on vc
+
+pkgname=krita
+pkgver=3.3.3
+pkgrel=2
+pkgdesc="Edit and paint images"
+arch=(x86_64)
+url="https://krita.org"
+license=(GPL3)
+depends=(kio kitemmodels gsl libraw exiv2 openexr fftw curl boost-libs)
+makedepends=(extra-cmake-modules kdoctools python boost eigen poppler-qt5 opencolorio)
+optdepends=('poppler-qt5: PDF filter' 'ffmpeg: to save animations' 'opencolorio: for the LUT docker' "krita-plugin-gmic: G'MIC plugin")
+conflicts=(calligra-krita krita-l10n)
+replaces=(calligra-krita krita-l10n)
+source=("https://download.kde.org/stable/krita/$pkgver/$pkgname-$pkgver.tar.gz"{,.sig})
+sha256sums=('bec04e3392e9b311477c5c6a50e2201b43a3afda91d9b24a0fc8e3399585865d'
+            'SKIP')
+validpgpkeys=('05D00A8B73A686789E0A156858B9596C722EA3BD') # Boudewijn Rempt <foundation@krita.org>
+
+prepare() {
+  mkdir -p build
+}
+
+build() {
+  cd build
+  cmake ../$pkgname-$pkgver \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_INSTALL_LIBDIR=lib \
+    -DBUILD_TESTING=OFF
+  make
+}
+
+package() {
+  cd build
+  make DESTDIR="$pkgdir" install
+}