added raspberrypi-utils

Replacement for raspberrypi-firmware.  This package is not needed
since upstream has moved to standard linux APIs.

alarm/raspberrypi-utils/10-raspberrypi-utils.rules

@@ -0,0 +1 @@
+KERNEL=="vcio",GROUP="video",MODE="0660"

alarm/raspberrypi-utils/PKGBUILD

@@ -0,0 +1,33 @@
+# Maintainer: graysky <therealgraysky AT protonmail DOT com>
+
+pkgname=raspberrypi-utils
+pkgver=20231020
+pkgrel=1
+_commit=a8ff215188e1e993146f72aa8526e1a3b2324316
+pkgdesc="Legacy scripts and simple applications for Raspberry Pi"
+arch=('aarch64' 'armv7h')
+url="https://github.com/raspberrypi/utils"
+license=('custom')
+makedepends=('cmake' 'dtc')
+replaces=('raspberrypi-firmware')
+conflicts=('raspberrypi-firmware')
+options=(!strip)
+source=("utils-$pkgver-$pkgrel-${_commit:0:10}.tar.gz::https://github.com/raspberrypi/utils/archive/$_commit.tar.gz"
+10-raspberrypi-utils.rules)
+md5sums=('b7da23db8bf492b41686179bf411e802'
+         'a0423d9850cc56a15967e103c351c335')
+
+build() {
+  cd "utils-$_commit"
+  cmake -S . -B . -DCMAKE_INSTALL_PREFIX=/usr
+  make
+}
+
+package() {
+  cd "utils-${_commit}"
+  make install DESTDIR="$pkgdir"
+  install -Dm0644 LICENCE -t "$pkgdir/usr/share/licenses/$pkgname"
+
+  # setup permissions on video group for /usr/bin/vcgencmd
+  install -Dm0644 ../10-raspberrypi-utils.rules "$pkgdir/usr/lib/udev/rules.d/10-raspberrypi-utils.rules"
+}