added alarm/polkit-117

alarm/polkit-117/PKGBUILD

@@ -0,0 +1,67 @@
+# Maintainer: Jan de Groot <jgc@archlinux.org>
+
+# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
+#  - v5 package until rust can be built and this can use js78
+
+buildarch=2
+
+pkgname=polkit-117
+_pkgname=polkit
+pkgver=0.117
+pkgrel=1
+pkgdesc="Application development toolkit for controlling system-wide privileges"
+arch=(x86_64)
+license=(LGPL)
+url="https://www.freedesktop.org/wiki/Software/polkit/"
+depends=(glib2 pam expat systemd js68)
+makedepends=(intltool gtk-doc gobject-introspection git autoconf-archive)
+provides=(polkit)
+replaces=(polkit)
+backup=(etc/pam.d/polkit-1)
+_commit=585f4f2715639394e36319d4918389d26e250e7b
+source=("git+https://gitlab.freedesktop.org/polkit/polkit.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $_pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $_pkgname
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+  cd $_pkgname
+
+  ./configure --prefix=/usr --sysconfdir=/etc \
+      --localstatedir=/var --libexecdir=/usr/lib \
+      --enable-libsystemd-login=yes --disable-static \
+      --enable-gtk-doc --with-os-type=redhat
+
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+
+  make
+}
+
+check() {
+  cd $_pkgname
+  make -k check || :
+}
+
+package() {
+  cd $_pkgname
+  make DESTDIR="$pkgdir" install \
+      dbusconfdir=/usr/share/dbus-1/system.d \
+      rulesdir=/usr/share/polkit-1/rules.d
+
+  install -d -o root -g 102 -m 750 "$pkgdir"/{etc,usr/share}/polkit-1/rules.d
+
+  install -Dm644 /dev/stdin "$pkgdir/usr/lib/sysusers.d/$_pkgname.conf" <<END
+u polkitd 102 "PolicyKit daemon"
+m polkitd proc
+END
+}
+
+# vim: ts=2 sw=2 et: