added extra/calligra

extra/calligra/PKGBUILD

@@ -0,0 +1,225 @@
+# $Id: PKGBUILD 184364 2013-05-06 19:36:46Z foutrelis $
+# Maintainer: Ronald van Haren <ronald.archlinux.org>
+# Maintainer: Andrea Scarpino <andrea@archlinux.org>
+
+# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
+#  - removed makedepend on vc - not for ARM
+
+pkgbase=calligra
+pkgname=('calligra-filters'
+         'calligra-libs'
+         'calligra-plugins'
+         'calligra-tools'
+         'calligra-karbon'
+         'calligra-kexi'
+         'calligra-plan'
+         'calligra-stage'
+         'calligra-krita'
+         'calligra-sheets'
+         'calligra-words'
+         'calligra-handbook'
+         'calligra-braindump'
+         'calligra-flow')
+pkgver=2.6.3
+pkgrel=4
+arch=('i686' 'x86_64')
+url='http://www.calligra-suite.org/'
+license=('FDL1.2' 'GPL2' 'LGPL')
+makedepends=('cmake' 'automoc4' 'boost' 'kdepimlibs' 'eigen2' 'kdeedu-marble'
+             'lcms2' 'libmariadbclient' 'freetds' 'xbase' 'libwpg' 'opencolorio'
+             'libwps' 'gsl' 'glew' 'fftw' 'opengtl' 'poppler-qt' 'libkdcraw'
+             'openjpeg' 'kdegraphics-okular' 'pstoedit')
+groups=('calligra')
+source=("http://download.kde.org/stable/${pkgbase}-${pkgver}/${pkgbase}-${pkgver}.tar.bz2")
+md5sums=('90d6bb619191abbcc94094379d47e225')
+
+build() {
+  mkdir build
+  cd build
+  cmake ../${pkgbase}-${pkgver} \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DBUILD_active=OFF
+  make
+}
+
+package_calligra-filters() {
+  pkgdesc="Filters for the Calligra office suite"
+  optdepends=('libwpg: Corel WordPerfect Graphics image importer'
+              'libwps: Microsoft Works file word processor format import')
+  conflicts=('koffice-filters')
+  replaces=('koffice-filters')
+  install=calligra-filters.install
+
+  cd "${srcdir}"/build/filters
+  make DESTDIR="${pkgdir}" install
+}
+
+package_calligra-libs() {
+  pkgdesc="Libraries for the Calligra office suite"
+  depends=('kdepimlibs' 'lcms2' 'kactivities')
+  conflicts=('koffice-interfaces' 'koffice-libs' 'koffice-pics'
+             'koffice-servicetypes' 'koffice-templates' 'calligra-interfaces'
+             'calligra-pics' 'calligra-servicetypes' 'calligra-templates')
+  replaces=('koffice-interfaces' 'koffice-libs' 'koffice-pics'
+             'koffice-servicetypes' 'koffice-templates' 'calligra-interfaces'
+             'calligra-pics' 'calligra-servicetypes' 'calligra-templates')
+
+  for d in interfaces libs pics servicetypes templates; do
+    cd "${srcdir}"/build/${d}
+    make DESTDIR="${pkgdir}" install
+  done
+}
+
+package_calligra-plugins() {
+  pkgdesc="Plugins for the Calligra office suite"
+  depends=('calligra-libs' 'calligra-filters')
+  optdepends=('kdeedu-marble: map shape for Calligra')
+  conflicts=('koffice-plugins' 'koffice-kchart')
+  replaces=('koffice-plugins' 'koffice-kchart' 'koffice-kformula')
+  install=calligra-plugins.install
+
+  cd "${srcdir}"/build/plugins
+  make DESTDIR="${pkgdir}" install
+}
+
+package_calligra-tools() {
+  pkgdesc="Tools for the Calligra office suite"
+  depends=('calligra-libs')
+  conflicts=('koffice-tools')
+  replaces=('koffice-tools')
+  install=calligra-tools.install
+
+  cd "${srcdir}"/build/tools
+  make DESTDIR="${pkgdir}" install
+}
+
+package_calligra-karbon() {
+  pkgdesc="Create scalable vector drawings"
+  depends=('calligra-libs' 'kdebase-runtime' 'pstoedit')
+  optdepends=('calligra-filters: import/export filters'
+              'calligra-tools: extra calligra tools')
+  conflicts=('koffice-karbon' 'koffice-karbon-doc' 'calligra-karbon-doc')
+  replaces=('koffice-karbon' 'koffice-karbon-doc' 'calligra-karbon-doc')
+  install=calligra-karbon.install
+
+  cd "${srcdir}"/build/karbon
+  make DESTDIR="${pkgdir}" install
+}
+
+package_calligra-kexi() {
+  pkgdesc="Develop desktop database applications"
+  depends=('calligra-libs' 'glew' 'fftw')
+  optdepends=('libmariadbclient: MariaDB driver'
+              'freetds: Sybase & MS SQL driver'
+              'xbase: XBase driver'
+              'calligra-sheets: Spreadsheet-to-Kexi-table import plugin'
+              'kdeedu-marble: map form widget'
+              'calligra-plugins: extra calligra plugins')
+  conflicts=('koffice-kexi' 'koffice-kexi-doc' 'calligra-kexi-doc')
+  replaces=('koffice-kexi' 'koffice-kexi-doc' 'calligra-kexi-doc')
+  install=calligra-kexi.install
+
+  cd "${srcdir}"/build/kexi
+  make DESTDIR="${pkgdir}" install
+  cd "${srcdir}"/build/doc/kexi
+  make DESTDIR="${pkgdir}" install
+}
+
+package_calligra-plan() {
+  pkgdesc="Calligra Project Management Component"
+  depends=('calligra-words')
+  conflicts=('koffice-kplato' 'calligra-kplato')
+  replaces=('koffice-kplato' 'calligra-kplato')
+  install=calligra-plan.install
+
+  cd "${srcdir}"/build/plan
+  make DESTDIR="${pkgdir}" install
+
+  cd "${srcdir}"/build/3rdparty/kdgantt
+  make DESTDIR="${pkgdir}" install
+}
+
+package_calligra-stage() {
+  pkgdesc="Write presentation documents"
+  depends=('calligra-plugins' 'kdebase-runtime')
+  conflicts=('koffice-kpresenter' 'koffice-kpresenter-doc' 'calligra-stage-doc')
+  replaces=('koffice-kpresenter' 'koffice-kpresenter-doc' 'calligra-stage-doc')
+  install=calligra-stage.install
+
+  cd "${srcdir}"/build/stage
+  make DESTDIR="${pkgdir}" install
+  cd "${srcdir}"/build/doc/stage
+  make DESTDIR="${pkgdir}" install
+}
+
+package_calligra-krita() {
+  pkgdesc="Edit and paint images"
+  depends=('calligra-plugins' 'kdebase-runtime' 'eigen2'
+           'opencolorio' 'libkdcraw' 'fftw' 'glew' 'opengtl')
+  conflicts=('koffice-krita' 'calligra-krita-doc')
+  replaces=('koffice-krita' 'calligra-krita-doc')
+  install=calligra-krita.install
+
+  cd "${srcdir}"/build/krita
+  make DESTDIR="${pkgdir}" install
+}
+
+package_calligra-sheets() {
+  pkgdesc="Write spreadsheet documents"
+  depends=('calligra-libs' 'gsl' 'kdebase-runtime')
+  optdepends=('calligra-filters: import/export filters'
+              'calligra-plugins: extra calligra plugins'
+              'calligra-tools: extra calligra tools')
+  conflicts=('koffice-kspread' 'koffice-kspread-doc' 'calligra-tables-doc' 'calligra-tables')
+  replaces=('koffice-kspread' 'koffice-kspread-doc' 'calligra-tables-doc' 'calligra-tables')
+  install=calligra-sheets.install
+
+  cd "${srcdir}"/build/sheets
+  make DESTDIR="${pkgdir}" install
+  cd "${srcdir}"/build/doc/sheets
+  make DESTDIR="${pkgdir}" install
+}
+
+package_calligra-words() {
+  pkgdesc="Word Processor"
+  depends=('calligra-plugins' 'kdegraphics-okular')
+  optdepends=('calligra-tools: extra calligra tools')
+  conflicts=('koffice-kword')
+  replaces=('koffice-kword')
+  install=calligra-words.install
+
+  cd "${srcdir}"/build/words
+  make DESTDIR="${pkgdir}" install
+}
+
+package_calligra-handbook() {
+  pkgdesc="Documentation for Calligra"
+  conflicts=('koffice-handbook')
+  replaces=('koffice-handbook')
+  options=('docs')
+
+  cd "${srcdir}"/build/doc/calligra
+  make DESTDIR="${pkgdir}" install
+}
+
+package_calligra-braindump() {
+  pkgdesc="Notes and idea gathering"
+  depends=('calligra-libs' 'kdebase-runtime')
+  install=calligra-braindump.install
+
+  cd "${srcdir}"/build/braindump
+  make DESTDIR="${pkgdir}" install
+}
+
+package_calligra-flow() {
+  pkgdesc="Flowchart & Diagram Editing"
+  depends=('calligra-words')
+  conflicts=('calligra-flow-doc')
+  replaces=('calligra-flow-doc')
+  install=calligra-flow.install
+  optdepends=('calligra-karbon: to export the charts in various formats')
+
+  cd "${srcdir}"/build/flow
+  make DESTDIR="${pkgdir}" install
+}

extra/calligra/calligra-braindump.install

@@ -0,0 +1,12 @@
+post_install() {
+	xdg-icon-resource forceupdate --theme hicolor &> /dev/null
+	update-desktop-database -q
+}
+
+post_upgrade() {
+	post_install
+}
+
+post_remove() {
+	post_install
+}

extra/calligra/calligra-filters.install

@@ -0,0 +1,11 @@
+post_install() {
+	update-mime-database usr/share/mime &> /dev/null
+}
+
+post_upgrade() {
+	post_install
+}
+
+post_remove() {
+	post_install
+}

extra/calligra/calligra-flow.install

@@ -0,0 +1,12 @@
+post_install() {
+	xdg-icon-resource forceupdate --theme hicolor &> /dev/null
+	update-desktop-database -q
+}
+
+post_upgrade() {
+	post_install
+}
+
+post_remove() {
+	post_install
+}

extra/calligra/calligra-karbon.install

@@ -0,0 +1,12 @@
+post_install() {
+	xdg-icon-resource forceupdate --theme hicolor &> /dev/null
+	update-desktop-database -q
+}
+
+post_upgrade() {
+	post_install
+}
+
+post_remove() {
+	post_install
+}

extra/calligra/calligra-kexi.install

@@ -0,0 +1,12 @@
+post_install() {
+	update-desktop-database -q
+    xdg-icon-resource forceupdate --theme hicolor &> /dev/null
+}
+
+post_upgrade() {
+	post_install
+}
+
+post_remove() {
+	post_install
+}

extra/calligra/calligra-krita.install

@@ -0,0 +1,13 @@
+post_install() {
+	xdg-icon-resource forceupdate --theme hicolor &> /dev/null
+	update-mime-database usr/share/mime &> /dev/null
+	update-desktop-database -q
+}
+
+post_upgrade() {
+	post_install
+}
+
+post_remove() {
+	post_install
+}

extra/calligra/calligra-plan.install

@@ -0,0 +1,12 @@
+post_install() {
+	xdg-icon-resource forceupdate --theme hicolor &> /dev/null
+	update-desktop-database -q
+}
+
+post_upgrade() {
+	post_install
+}
+
+post_remove() {
+	post_install
+}

extra/calligra/calligra-plugins.install

@@ -0,0 +1,11 @@
+post_install() {
+    update-mime-database usr/share/mime &> /dev/null
+}
+
+post_upgrade() {
+	post_install
+}
+
+post_remove() {
+	post_install
+}

extra/calligra/calligra-sheets.install

@@ -0,0 +1,12 @@
+post_install() {
+	xdg-icon-resource forceupdate --theme hicolor &> /dev/null
+	update-desktop-database -q
+}
+
+post_upgrade() {
+	post_install
+}
+
+post_remove() {
+	post_install
+}

extra/calligra/calligra-stage.install

@@ -0,0 +1,12 @@
+post_install() {
+	xdg-icon-resource forceupdate --theme hicolor &> /dev/null
+	update-desktop-database -q
+}
+
+post_upgrade() {
+	post_install
+}
+
+post_remove() {
+	post_install
+}

extra/calligra/calligra-tools.install

@@ -0,0 +1,12 @@
+post_install() {
+	xdg-icon-resource forceupdate --theme hicolor &> /dev/null
+	update-desktop-database -q
+}
+
+post_upgrade() {
+	post_install
+}
+
+post_remove() {
+	post_install
+}

extra/calligra/calligra-words.install

@@ -0,0 +1,12 @@
+post_install() {
+	xdg-icon-resource forceupdate --theme hicolor &> /dev/null
+	update-desktop-database -q
+}
+
+post_upgrade() {
+	post_install
+}
+
+post_remove() {
+	post_install
+}

extra/calligra/calligra.install

@@ -0,0 +1,11 @@
+post_install() {
+	xdg-icon-resource forceupdate --theme hicolor &> /dev/null
+}
+
+post_upgrade() {
+	post_install
+}
+
+post_remove() {
+	post_install
+}