added community/motion

community/motion/PKGBUILD

@@ -0,0 +1,45 @@
+# $Id$
+# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
+
+# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
+#  - remove bad CFLAGS addition
+
+pkgname=motion
+pkgver=4.0.1
+pkgrel=1.1
+pkgdesc="A software motion detector which grabs images from video4linux devices and/or from webcams"
+arch=('i686' 'x86_64')
+license=('GPL')
+url="http://www.lavrsen.dk/foswiki/bin/view/Motion/WebHome"
+depends=('libjpeg' 'v4l-utils' 'ffmpeg')
+backup=('etc/motion/motion.conf')
+options=('!makeflags')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/Motion-Project/motion/archive/release-$pkgver.tar.gz"
+	motion.service
+	motion.tmpfiles)
+md5sums=('5c87f90c4118d8cf0fb14700db69118f'
+         'c8e9a9e9fd2dcc1ee8bcee1f32a91559'
+         'f863f8c025f7f025b2178def8418decd')
+
+build() {
+  cd "${srcdir}/${pkgname}-release-${pkgver}"
+
+  # remove bad CFLAGS addition
+  sed -i 's/-march=native -mtune=native//' configure.ac
+
+  autoreconf
+  ./configure --prefix=/usr \
+    --without-pgsql \
+    --without-mysql \
+    --sysconfdir=/etc \
+    --with-ffmpeg
+  make
+}
+
+package(){
+  cd "${srcdir}/${pkgname}-release-${pkgver}"
+  make DESTDIR="${pkgdir}" install
+  mv "${pkgdir}/etc/motion/motion-dist.conf" "${pkgdir}/etc/motion/motion.conf"
+  install -Dm644 "${srcdir}/motion.service" "${pkgdir}/usr/lib/systemd/system/motion.service"
+  install -Dm644 "${srcdir}/motion.tmpfiles" "${pkgdir}/usr/lib/tmpfiles.d/motion.conf"
+}

community/motion/motion.service

@@ -0,0 +1,13 @@
+[Unit]
+Description=Motion daemon
+After=local-fs.target
+
+[Service]
+PIDFile=/run/motion/motion.pid
+ExecStart=/usr/bin/motion
+Type=forking
+#StandardOutput=null
+StandardError=null
+
+[Install]
+WantedBy=multi-user.target

community/motion/motion.tmpfiles

@@ -0,0 +1 @@
+D /var/run/motion 0755 root root