archlinuxarm/PKGBUILDs
1
0
Fork 0
mirror of https://github.com/archlinuxarm/PKGBUILDs.git synced 2024-09-19 22:08:32 +00:00
Code Issues Actions Packages Projects Releases Wiki Activity

aur/python2-certifi -> community/python-certifi 14.05.14-1

Browse source
This commit is contained in:
Kevin Mihelich 2014-07-23 11:34:30 +00:00
parent 5f168e8d0c
commit 9a5bb86a99
2 changed files with 50 additions and 33 deletions
Show stats Download patch file Download diff file Expand all files Collapse all files

33
aur/python2-certifi/PKGBUILD
View file

@ -1,33 +0,0 @@
# $Id: PKGBUILD 81227 2012-12-13 19:50:09Z mtorromeo $
# Maintainer: Massimiliano Torromeo <massimiliano.torromeo@gmail.com>
# Contributor: William J Bowman <bluephoenix47@gmail.com>
pkgname=python2-certifi
_libname=${pkgname/python2-/}
pkgver=1.0.1
pkgrel=1
pkgdesc="Mozilla's SSL Certs"
arch=(any)
url="http://pypi.python.org/pypi/certifi"
license=('GPL')
depends=('python2')
makedepends=('python2-setuptools')
source=(http://pypi.python.org/packages/source/${_libname:0:1}/$_libname/$_libname-$pkgver.tar.gz)
prepare() {
cd "$srcdir/$_libname-$pkgver"
sed -i '1 s|python$|python2|' certifi/core.py
}
build() {
cd "$srcdir/$_libname-$pkgver"
python2 setup.py build
}
package() {
cd "$srcdir/$_libname-$pkgver"
python2 setup.py install --skip-build -O1 --root="$pkgdir"
install -m0644 -D "LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
sha256sums=('f2c18c7edd349ec10378ef43ff16f81ae1d0af61d5d2858a8b383e8f6814a9cc')

50
community/python-certifi/PKGBUILD Normal file
View file

@ -0,0 +1,50 @@
# $Id$
# Maintainer: Felix Yan <felixonmars@gmail.com>
# Contributor: Massimiliano Torromeo <massimiliano.torromeo@gmail.com>
# Contributor: William J Bowman <bluephoenix47@gmail.com>
# remove when bumped upstream
pkgbase=python-certifi
pkgname=('python-certifi' 'python2-certifi')
_libname=${pkgbase/python-/}
pkgver=14.05.14
pkgrel=1
pkgdesc="Mozilla's SSL Certs"
arch=(any)
url="http://pypi.python.org/pypi/certifi"
license=('GPL')
makedepends=('python-setuptools' 'python2-setuptools')
source=("http://pypi.python.org/packages/source/${_libname:0:1}/$_libname/$_libname-$pkgver.tar.gz")
sha512sums=('5edba0cc432c27212e31085fb3c2f2ded6fa177d716116111517c25b980d9fc206a9a6d47e2c001762e951ff50203b269d0eb245a039df20188b1136f3b700b2')
prepare() {
cp -a $_libname-$pkgver{,-py2}
cd $_libname-$pkgver-py2
sed -i '1s|python$|python2|' certifi/core.py
}
build() {
cd "$srcdir/$_libname-$pkgver"
python setup.py build
cd "$srcdir/$_libname-$pkgver-py2"
python2 setup.py build
}
package_python-certifi() {
depends=('python')
cd "$srcdir/$_libname-$pkgver"
python setup.py install --skip-build -O1 --root="$pkgdir"
install -m0644 -D "LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
package_python2-certifi() {
depends=('python2')
cd "$srcdir/$_libname-$pkgver-py2"
python2 setup.py install --skip-build -O1 --root="$pkgdir"
install -m0644 -D "LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}