diff --git a/extra/tracker-miners/PKGBUILD b/extra/tracker-miners/PKGBUILD
new file mode 100644
index 000000000..957d3b885
--- /dev/null
+++ b/extra/tracker-miners/PKGBUILD
@@ -0,0 +1,45 @@
+# $Id$
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
+
+# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
+#  - makedepend on vala
+
+pkgname=tracker-miners
+pkgver=2.1.0
+pkgrel=1
+pkgdesc="Collection of data extractors for Tracker/Nepomuk"
+url="https://wiki.gnome.org/Projects/Tracker"
+arch=(x86_64)
+license=(GPL)
+depends=(tracker gst-plugins-base-libs exempi flac libexif libcue libgrss libgsf libgxps
+         libiptcdata libosinfo libvorbis poppler-glib taglib totem-plparser giflib)
+makedepends=(intltool git python meson vala)
+groups=(gnome)
+_commit=24d32b563e6bfba4558c8bcb4724b19a14e1513b  # tags/2.1.0^0
+source=("git+https://gitlab.gnome.org/GNOME/tracker-miners.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+}
+
+build() {
+  arch-meson $pkgname build
+  ninja -C build
+}
+
+check() {
+  # Many tests are broken:
+  # - Assume schemas are installed
+  # - Assume services are autolaunched
+  dbus-run-session meson test -C build || :
+}
+
+package() {
+  DESTDIR="$pkgdir" meson install -C build
+}