added community/sundials

community/sundials/PKGBUILD

@@ -0,0 +1,45 @@
+# Maintainer: Antonio Rojas <arojas@archlinux.org>
+# Contributor: Elmar Klausmeier <Elmar.Klausmeier@gmail.com>
+
+# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
+#  - set SUNDIALS_INDEX_TYPE for 32-bit ARM
+
+pkgname=sundials
+pkgver=4.1.0
+pkgrel=2.1
+pkgdesc="Suite of nonlinear differential/algebraic equation solvers"
+arch=(x86_64)
+url="https://computation.llnl.gov/casc/sundials/main.html"
+license=(BSD)
+depends=(openmpi suitesparse)
+makedepends=(cmake gcc-fortran python)
+source=("https://computation.llnl.gov/projects/sundials/download/$pkgname-$pkgver.tar.gz")
+sha256sums=('280de1c27b2360170a6f46cb3799b2aee9dff3bddbafc8b08c291a47ab258aa5')
+
+prepare() {
+  mkdir -p build
+}
+
+build() {
+  cd build
+  [[ $CARCH != "aarch64" ]] && CONFIG="-DSUNDIALS_INDEX_TYPE=int32_t"
+  cmake ../$pkgname-$pkgver \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_INSTALL_LIBDIR=lib \
+    -DMPI_ENABLE=ON \
+    -DPTHREAD_ENABLE=ON	\
+    -DOPENMP_ENABLE=ON \
+    -DF77_INTERFACE_ENABLE=ON \
+    -DKLU_ENABLE=ON \
+    -DKLU_LIBRARY_DIR=/usr/lib \
+    -DEXAMPLES_INSTALL_PATH=/usr/share/sundials/examples $CONFIG
+  make
+}
+
+package() {
+  cd build
+  make DESTDIR="$pkgdir" install
+
+  install -Dm644 "$srcdir"/$pkgname-$pkgver/LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname
+}
+