added community/pynormaliz

community/pynormaliz/0001-AArch64-fix.patch

@@ -0,0 +1,25 @@
+From 4aa59d4efe5c2001f0de3ac0d28c7aa78696d3b2 Mon Sep 17 00:00:00 2001
+From: Kevin Mihelich <kevin@archlinuxarm.org>
+Date: Fri, 6 Jan 2017 20:46:03 -0700
+Subject: [PATCH] AArch64 fix
+
+---
+ NormalizModule.cpp | 2 +-
+ 1 file changed, 1 insertion(+), 1 deletion(-)
+
+diff --git a/NormalizModule.cpp b/NormalizModule.cpp
+index e25de74..ee17989 100644
+--- a/NormalizModule.cpp
++++ b/NormalizModule.cpp
+@@ -60,7 +60,7 @@ static string cone_name_str_long( cone_name_long );
+ 
+ // Check GCC
+ #if __GNUC__
+-#if __x86_64__ || __ppc64__
++#if __x86_64__ || __ppc64__ || __aarch64__
+ #define ENVIRONMENT64
+ #else
+ #define ENVIRONMENT32
+-- 
+2.10.2
+

community/pynormaliz/PKGBUILD

@@ -0,0 +1,46 @@
+# Maintainer: Antonio Rojas <arojas@archlinux.org>
+
+# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
+#  - patch to fix AArch64 build
+
+pkgbase=pynormaliz
+pkgname=(python2-pynormaliz python-pynormaliz)
+pkgver=1.1
+pkgrel=2
+pkgdesc="A Python interface to Normaliz"
+arch=(i686 x86_64)
+url="https://github.com/sebasguts/PyNormaliz"
+license=(GPL2)
+makedepends=(python-setuptools python2-setuptools normaliz)
+source=("https://pypi.io/packages/source/P/PyNormaliz/PyNormaliz-$pkgver.tar.gz"
+        '0001-AArch64-fix.patch')
+md5sums=('d36a2b6b53a095b5c09544a5d0662178'
+         '456c661216d76a0f819650f79974626b')
+
+prepare() {
+  patch -p1 -d PyNormaliz-$pkgver -i "${srcdir}/0001-AArch64-fix.patch"
+  cp -r PyNormaliz-$pkgver PyNormaliz-$pkgver-py2
+}
+
+build() {
+  cd PyNormaliz-$pkgver
+  python setup.py build
+
+  cd ../PyNormaliz-$pkgver-py2
+  python2 setup.py build
+}
+
+package_python2-pynormaliz() {
+  depends=(python2 normaliz)
+  cd PyNormaliz-$pkgver-py2
+
+  python2 setup.py install --prefix=/usr --root="$pkgdir" --optimize=1
+}
+
+package_python-pynormaliz() {
+  depends=(python normaliz)
+  cd PyNormaliz-$pkgver
+  
+  python setup.py install --prefix=/usr --root="$pkgdir" --optimize=1
+}
+