removed extra/spirv-llvm-translator

extra/spirv-llvm-translator/.SRCINFO

@@ -1,20 +0,0 @@
-pkgbase = spirv-llvm-translator
-	pkgdesc = Tool and a library for bi-directional translation between SPIR-V and LLVM IR
-	pkgver = 17.0.0.r6+g70883514
-	pkgrel = 1
-	url = https://github.com/KhronosGroup/SPIRV-LLVM-Translator
-	arch = x86_64
-	license = custom
-	checkdepends = python
-	checkdepends = python-setuptools
-	checkdepends = clang
-	makedepends = git
-	makedepends = cmake
-	makedepends = llvm
-	makedepends = spirv-headers
-	depends = llvm-libs
-	depends = spirv-tools
-	source = git+https://github.com/KhronosGroup/SPIRV-LLVM-Translator.git#commit=7088351420a8f0c3e5f9be678fd1d16ae826e37f
-	sha256sums = SKIP
-
-pkgname = spirv-llvm-translator

extra/spirv-llvm-translator/PKGBUILD

@@ -1,50 +0,0 @@
-# Maintainer: Daniel Bermond <dbermond@archlinux.org>
-# Maintainer: Bruno Pagani <archange@archlinux.org>
-
-# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
-#  - make llvm-spirv, install doesn't work otherwise
-
-_srcname=SPIRV-LLVM-Translator
-pkgname=${_srcname,,}
-pkgver=17.0.0.r6+g70883514
-pkgrel=1
-pkgdesc="Tool and a library for bi-directional translation between SPIR-V and LLVM IR"
-arch=(x86_64)
-url="https://github.com/KhronosGroup/SPIRV-LLVM-Translator"
-license=(custom)
-depends=(llvm-libs spirv-tools)
-makedepends=(git cmake llvm spirv-headers)
-checkdepends=(python python-setuptools clang)
-# Current point in the used LLVM branch
-_commit=7088351420a8f0c3e5f9be678fd1d16ae826e37f
-source=(git+${url}.git#commit=$_commit)
-sha256sums=('SKIP')
-
-pkgver() {
-  cd ${_srcname}
-  git describe --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./;s/-/+/'
-}
-
-build() {
-  cmake -B build -S ${_srcname} \
-    -DBUILD_SHARED_LIBS=ON \
-    -DCMAKE_BUILD_TYPE=Release \
-    -DCMAKE_INSTALL_PREFIX=/usr \
-    -DCMAKE_POSITION_INDEPENDENT_CODE=ON \
-    -DCMAKE_SKIP_RPATH=ON \
-    -DLLVM_INCLUDE_TESTS=ON \
-    -DLLVM_EXTERNAL_LIT=/usr/bin/lit \
-    -DLLVM_EXTERNAL_SPIRV_HEADERS_SOURCE_DIR=/usr/include/spirv/ \
-    -Wno-dev
-  make -C build llvm-spirv
-}
-
-check() {
-  LD_LIBRARY_PATH="${srcdir}/build/lib/SPIRV" make -C build test
-}
-
-package() {
-  make -C build DESTDIR="${pkgdir}" install
-  install -Dm755 build/tools/llvm-spirv/llvm-spirv -t "${pkgdir}"/usr/bin
-  install -Dm644 ${_srcname}/LICENSE.TXT -t "${pkgdir}"/usr/share/licenses/${pkgname}/
-}