added extra/libunwind

extra/libunwind/PKGBUILD

@@ -0,0 +1,46 @@
+# $id$
+# Maintainer: Sébastien Luttringer
+# Contributor: Lawrence Lee <valheru@facticius.net>
+# Contributor: Phillip Marvin <phillip.marvin@gmail.com>
+# Contributor: keystone <phillip.marvin@gmail.com>
+
+# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
+#  - aarch64 support patch
+
+pkgname=libunwind
+pkgver=1.1
+pkgrel=2
+pkgdesc='Portable and efficient C programming interface (API) to determine the call-chain of a program'
+arch=('i686' 'x86_64')
+url='http://www.nongnu.org/libunwind/'
+license=('GPL')
+depends=('glibc' 'xz')
+source=("http://download.savannah.gnu.org/releases/$pkgname/$pkgname-$pkgver.tar.gz"
+        'libunwind-aarch64.patch')
+md5sums=('fb4ea2f6fbbe45bf032cd36e586883ce'
+         '5dd4c2661baa949389259a027d3b89e2')
+
+prepare() {
+  cd $pkgname-$pkgver
+  patch -p1 -i ../libunwind-aarch64.patch
+  autoreconf -fi
+}
+
+build() {
+  cd $pkgname-$pkgver
+  ./configure CFLAGS="$CFLAGS -U_FORTIFY_SOURCE" --prefix=/usr
+  make
+}
+
+check() {
+  cd $pkgname-$pkgver
+  # This function is ``supposed'' to fail. Upstream know, but haven't fixed it.
+  make check || return 0
+}
+
+package() {
+  cd $pkgname-$pkgver
+  make DESTDIR="$pkgdir/" install
+}
+
+# vim:set ts=2 sw=2 et: