removed community/libjxl

community/libjxl/PKGBUILD

@@ -1,96 +0,0 @@
-# Maintainer: Daniel Bermond <dbermond@archlinux.org>
-
-# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
-#  - explicitly link v5 with libatomic
-
-pkgbase=libjxl
-pkgname=('libjxl' 'libjxl-doc')
-pkgver=0.6.1
-pkgrel=3
-pkgdesc='JPEG XL image format reference implementation'
-arch=('x86_64')
-url='https://jpeg.org/jpegxl/'
-license=('BSD')
-makedepends=('git' 'cmake' 'clang' 'brotli' 'gdk-pixbuf2' 'giflib' 'gimp'
-             'gperftools' 'libjpeg-turbo' 'libpng' 'openexr' 'gtest'
-             'java-environment' 'python' 'asciidoc' 'doxygen' 'graphviz'
-             'xdg-utils' 'highway')
-options=('!lto')
-source=("git+https://github.com/libjxl/libjxl.git#tag=v${pkgver}"
-        'git+https://github.com/google/brotli.git'
-        'git+https://github.com/lvandeve/lodepng.git'
-        'git+https://github.com/mm2/Little-CMS.git'
-        'git+https://github.com/google/googletest.git'
-        'git+https://github.com/webmproject/sjpeg.git'
-        'git+https://skia.googlesource.com/skcms.git'
-        'git+https://github.com/google/highway.git')
-sha256sums=('SKIP'
-            'SKIP'
-            'SKIP'
-            'SKIP'
-            'SKIP'
-            'SKIP'
-            'SKIP'
-            'SKIP')
-
-prepare() {
-    git -C libjxl submodule init
-    git -C libjxl config --local submodule.third_party/brotli.url "${srcdir}/brotli"
-    git -C libjxl config --local submodule.third_party/lodepng.url "${srcdir}/lodepng"
-    git -C libjxl config --local submodule.third_party/lcms.url "${srcdir}/Little-CMS"
-    git -C libjxl config --local submodule.third_party/googletest.url "${srcdir}/googletest"
-    git -C libjxl config --local submodule.third_party/sjpeg.url "${srcdir}/sjpeg"
-    git -C libjxl config --local submodule.third_party/skcms.url "${srcdir}/skcms"
-    git -C libjxl config --local submodule.third_party/highway.url "${srcdir}/highway"
-    git -C libjxl submodule update
-    if [[ $CARCH == "arm" ]]; then
-        echo "target_link_libraries(jxl PUBLIC atomic)" >> libjxl/lib/jxl.cmake
-        echo "target_link_libraries(jxl-static PUBLIC atomic)" >> libjxl/lib/jxl.cmake
-        echo "target_link_libraries(jxl_dec PUBLIC atomic)" >> libjxl/lib/jxl.cmake
-        echo "target_link_libraries(jxl_dec-static PUBLIC atomic)" >> libjxl/lib/jxl.cmake
-    fi
-}
-
-build() {
-    export CC='clang'
-    export CXX='clang++'
-    export CFLAGS+=' -DNDEBUG'
-    export CXXFLAGS+=' -DNDEBUG'
-    cmake -B build -S libjxl \
-        -DCMAKE_BUILD_TYPE:STRING='None' \
-        -DCMAKE_INSTALL_PREFIX:PATH='/usr' \
-        -DJPEGXL_ENABLE_BENCHMARK:BOOL='false' \
-        -DJPEGXL_ENABLE_EXAMPLES:BOOL='false' \
-        -DJPEGXL_ENABLE_FUZZERS:BOOL='false' \
-        -DJPEGXL_ENABLE_PLUGINS:BOOL='true' \
-        -DJPEGXL_ENABLE_VIEWERS:BOOL='false' \
-        -DJPEGXL_FORCE_SYSTEM_BROTLI:BOOL='true' \
-        -DJPEGXL_FORCE_SYSTEM_GTEST:BOOL='true' \
-        -DJPEGXL_FORCE_SYSTEM_HWY:BOOL='true' \
-        -Wno-dev
-    make -C build all doc
-}
-
-check() {
-    make -C build test
-}
-
-package_libjxl() {
-    depends=('brotli' 'giflib' 'gperftools' 'libjpeg-turbo' 'libpng' 'openexr')
-    optdepends=('gdk-pixbuf2: for gdk-pixbuf loader'
-                'gimp: for gimp plugin'
-                'java-runtime: for JNI bindings')
-    provides=('libjxl.so' 'libjxl_threads.so')
-    
-    make -C build DESTDIR="$pkgdir" install
-    install -D -m755 build/tools/libjxl_jni.so -t "${pkgdir}/usr/lib"
-    install -D -m644 libjxl/{LICENSE,PATENTS} -t "${pkgdir}/usr/share/licenses/${pkgname}"
-}
-
-package_libjxl-doc() {
-    pkgdesc+=' (documentation)'
-    
-    install -d -m755 "${pkgdir}/usr/share/doc"
-    install -D -m644 libjxl/{LICENSE,PATENTS} -t "${pkgdir}/usr/share/licenses/${pkgname}"
-    cp -dr --no-preserve='ownership' build/html "${pkgdir}/usr/share/doc/libjxl"
-}