added extra/wolfssl

extra/wolfssl/PKGBUILD

@@ -0,0 +1,53 @@
+# Maintainer: David Runge <dvzrv@archlinux.org>
+
+# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
+#  - cmake with -DWOLFSSL_SHA3=ON, required and not set by default for v7
+
+pkgname=wolfssl
+pkgver=5.3.0
+pkgrel=1
+pkgdesc="Lightweight, portable, C-language-based SSL/TLS library"
+arch=(x86_64)
+url="https://www.wolfssl.com/"
+license=(GPL2)
+depends=(glibc)
+makedepends=(cmake)
+provides=(libwolfssl.so)
+options=(debug)
+source=(
+  $pkgname-$pkgver-stable.tar.gz::https://github.com/$pkgname/$pkgname/archive/refs/tags/v$pkgver-stable.tar.gz
+  https://github.com/$pkgname/$pkgname/releases/download/v$pkgver-stable/$pkgname-$pkgver-stable.tar.gz.asc
+)
+sha512sums=('399d2b8aad58471d237d21dea68c33fde2b9a3c117c554c241d9174db02847a6c31afae2908839d18f9ada317b2388560a24c077b76014f663227061342bf045'
+            'SKIP')
+b2sums=('ad176c11959270d21c91104f030063f5e6241e7794b6309ea3ccffc7c106c05c5c4feea373fcf0eb68cb4f79d72c4680cd39d0b13984cd3dbc1d781e7ff673ba'
+        'SKIP')
+validpgpkeys=(
+  A2A48E7BCB96C5BECB987314EBC80E415CA29677  # wolfSSL <secure@wolfssl.com>
+)
+
+build() {
+  cmake \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_BUILD_TYPE=None \
+    -DWOLFSSL_CURVE25519=ON \
+    -DWOLFSSL_CURVE448=ON \
+    -DWOLFSSL_ED25519=ON \
+    -DWOLFSSL_ED448=ON \
+    -DWOLFSSL_SHA3=ON \
+    -DWOLFSSL_REPRODUCIBLE_BUILD=ON \
+    -Wno-dev \
+    -B build \
+    -S $pkgname-$pkgver-stable
+  cmake --build build --verbose
+}
+
+check() {
+  cd build
+  ctest --output-on-failure
+}
+
+package() {
+  DESTDIR="$pkgdir" cmake --install build
+  install -vDm 644 $pkgname-$pkgver-stable/{README,ChangeLog}.md -t "$pkgdir/usr/share/doc/$pkgname/"
+}