added community/rclone

reduced diffstat to upstream, closes #1821

community/rclone/PKGBUILD

@@ -0,0 +1,57 @@
+# Maintainer: Felix Yan <felixonmars@archlinux.org>
+# Maintainer: Morten Linderud <foxboron@archlinux.org>
+
+# ALARM: Lorenz Steinert <lsteinert@uraziel.de>
+#  - remove makedepends pandoc
+#  - remove rclone.1 MANUAL.html and MANUAL.txt targets from make in build()
+
+pkgname=rclone
+pkgver=1.52.3
+pkgrel=1
+pkgdesc="Sync files to and from Google Drive, S3, Swift, Cloudfiles, Dropbox and Google Cloud Storage"
+arch=('x86_64')
+url="https://rclone.org/"
+license=('MIT')
+depends=('glibc')
+optdepends=('fuse2: for rclone mount')
+makedepends=('python' 'go' 'git')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/rclone/rclone/archive/v$pkgver.tar.gz")
+sha512sums=('ef22477cbe000675e12ecf9d49b035053ab1cf6841ec89073395605fc8ccca25cf5390e8445911d451be4084ae4557452754db15f0937035ad7abe9aecaa2d3d')
+
+prepare() {
+  cd "rclone-$pkgver"
+  sed -i "1s/python$/&2/" bin/make_manual.py bin/make_backend_docs.py
+}
+
+build() {
+  cd "rclone-$pkgver"
+  
+  export GOFLAGS="-buildmode=pie -trimpath"
+  export CGO_LDFLAGS="${LDFLAGS}"
+  export CGO_CFLAGS="${CFLAGS}"
+  export CGO_CPPFLAGS="${CPPFLAGS}"
+
+  PATH=".:$PATH" make TAG=v$pkgver rclone
+ ./rclone genautocomplete bash rclone.bash_completion
+ ./rclone genautocomplete zsh rclone.zsh_completion
+}
+
+check() {
+  cd "rclone-$pkgver"
+  make TAG=v$pkgver test
+}
+
+package() {
+  cd "rclone-$pkgver"
+
+  install -Dm755 rclone "$pkgdir"/usr/bin/rclone
+
+  install -Dm644 rclone.bash_completion "$pkgdir"/usr/share/bash-completion/completions/rclone
+  install -Dm644 rclone.zsh_completion "$pkgdir"/usr/share/zsh/site-functions/_rclone
+
+  install -Dm644 COPYING "$pkgdir"/usr/share/licenses/$pkgname/COPYING
+
+  install -Dm644 rclone.1 "$pkgdir"/usr/share/man/man1/rclone.1
+  install -d "$pkgdir"/usr/share/doc/$pkgname
+  install -t "$pkgdir"/usr/share/doc/$pkgname -m644 MANUAL.html MANUAL.txt
+}