added extra/imlib2

extra/imlib2/PKGBUILD

@@ -0,0 +1,41 @@
+# Maintainer: Ronald van Haren <ronald.archlinux.org>
+# Contributor: Arjan Timmerman <arjan.archlinux.org>
+# Contributor: Tom Newsom <Jeepster.gmx.co.uk>
+
+# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
+#  - remove --enable-amd64 from configure
+
+pkgname=imlib2
+pkgver=1.7.5
+pkgrel=1
+pkgdesc="Library that does image file loading and saving as well as rendering, manipulation, arbitrary polygon support"
+url="https://sourceforge.net/projects/enlightenment/"
+arch=('x86_64')
+license=('BSD')
+depends=('libtiff' 'giflib' 'bzip2' 'freetype2' 'libxext' 'libpng' 'libid3tag' 'libjpeg-turbo' 'libwebp')
+source=(https://downloads.sourceforge.net/project/enlightenment/imlib2-src/$pkgver/$pkgname-$pkgver.tar.xz)
+sha512sums=('6e0a79359d6cac297b7a074a75bf577c8c1e3932d9993616834ea9076a7df544fafcfa960fe8ed7468f1291533f3c828260ccb809a882dadb3f3650ba9dd3f28')
+
+build() {
+  cd "${pkgname}-${pkgver}"
+
+  ./configure --prefix=/usr \
+              --sysconfdir=/etc/imlib2 \
+              --x-libraries=/usr/lib
+  make
+}
+
+
+check() {
+  cd "${pkgname}-${pkgver}"
+  make check
+}
+
+
+package() {
+  cd "${pkgname}-${pkgver}"
+  make DESTDIR="${pkgdir}" install
+
+  # Install License
+  install -Dm644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/COPYING"
+}